// Copyright (c) 2019-2024 Alexander Medvednikov. All rights reserved.
// Use of this source code is governed by an MIT license
// that can be found in the LICENSE file.
module c

import strings
import v.ast
import v.util

// has[int]() => has_T_int()
// has[int, string]() => has_T_int_string()
const c_fn_name_escape_seq = ['[', '_T_', ', ', '_', ']', '']

fn collect_function_defer_stmts(node &ast.FnDecl) []ast.DeferStmt {
    mut defer_stmts := []ast.DeferStmt{cap: node.defer_stmts.len}
    for defer_stmt in node.defer_stmts {
        if defer_stmt.mode == .function {
            defer_stmts << defer_stmt
        }
    }
    return defer_stmts
}

fn (g &Gen) method_decl_fkey(method ast.Fn) string {
    if method.source_fn != unsafe { nil } {
        fndecl := unsafe { &ast.FnDecl(method.source_fn) }
        return fndecl.fkey()
    }
    return method.fkey()
}

fn (g &Gen) receiver_exact_method_for_type(typ ast.Type, method_name string) ?ast.Fn {
    if typ == 0 {
        return none
    }
    sym := g.table.sym(typ)
    // A `mut` receiver is stored as a pointer (`&T`), so compare the base types
    // (ignoring the pointer level) to match such a method against both the value
    // and pointer forms of `typ`. See #27465.
    typ_base := typ.set_nr_muls(0)
    for method in sym.methods {
        if method.name == method_name && method.receiver_type.set_nr_muls(0) == typ_base {
            return method
        }
    }
    if sym.info is ast.Alias {
        parent_type := sym.info.parent_type.derive(typ)
        parent_base := parent_type.set_nr_muls(0)
        parent_sym := g.table.sym(parent_type)
        for method in parent_sym.methods {
            if method.name == method_name && method.receiver_type.set_nr_muls(0) == parent_base {
                return method
            }
        }
    }
    return none
}

fn (g &Gen) generic_parent_method_fkey(sym ast.TypeSymbol, method_name string) string {
    match sym.info {
        ast.Struct, ast.Interface, ast.SumType {
            if sym.info.parent_type.has_flag(.generic) {
                parent_sym := g.table.sym(sym.info.parent_type)
                if method := parent_sym.find_method(method_name) {
                    return g.method_decl_fkey(method)
                }
            }
        }
        ast.GenericInst {
            if sym.info.parent_idx > 0 {
                parent_sym := g.table.sym(ast.idx_to_type(sym.info.parent_idx))
                if method := parent_sym.find_method(method_name) {
                    return g.method_decl_fkey(method)
                }
            }
        }
        else {}
    }

    return ''
}

fn (g &Gen) resolve_method_decl_fkey_for_type(typ ast.Type, method_name string) string {
    mut candidate_types := []ast.Type{}
    for candidate in [typ] {
        if candidate == 0 {
            continue
        }
        if candidate !in candidate_types {
            candidate_types << candidate
        }
        unaliased := g.table.unaliased_type(candidate)
        if unaliased != 0 && unaliased != candidate && unaliased !in candidate_types {
            candidate_types << unaliased
        }
        if !candidate.is_ptr() {
            ref_typ := candidate.ref()
            if ref_typ != 0 && ref_typ !in candidate_types {
                candidate_types << ref_typ
            }
        }
        if candidate.is_ptr() {
            deref_typ := candidate.deref()
            if deref_typ != 0 && deref_typ !in candidate_types {
                candidate_types << deref_typ
            }
        }
    }
    for candidate in candidate_types {
        sym := g.table.sym(candidate)
        parent_fkey := g.generic_parent_method_fkey(sym, method_name)
        if parent_fkey != '' {
            return parent_fkey
        }
        if method := sym.find_method_with_generic_parent(method_name) {
            return g.method_decl_fkey(method)
        }
        if method := g.table.find_method(sym, method_name) {
            return g.method_decl_fkey(method)
        }
        method, embed_types := g.table.find_method_from_embeds(g.table.final_sym(candidate),
            method_name) or { ast.Fn{}, []ast.Type{} }
        if embed_types.len != 0 {
            return g.method_decl_fkey(method)
        }
    }
    return ''
}

fn free_method_calls_free_on_receiver(method ast.Fn) bool {
    if method.source_fn == unsafe { nil } {
        return false
    }
    fn_decl := unsafe { &ast.FnDecl(method.source_fn) }
    if fn_decl.receiver.name == '' {
        return false
    }
    root := ast.Node(ast.Stmt(*fn_decl))
    return free_method_calls_free_on_receiver_walk(root, fn_decl.receiver.name)
}

fn free_method_calls_free_on_receiver_walk(node ast.Node, receiver_name string) bool {
    if node is ast.Expr {
        match node {
            ast.AnonFn, ast.LambdaExpr {
                return false
            }
            ast.CallExpr {
                if node.name == 'free' && node.args.len == 1
                    && free_method_matches_receiver_expr(node.args[0].expr, receiver_name) {
                    return true
                }
            }
            else {}
        }
    }
    for child in node.children() {
        if free_method_calls_free_on_receiver_walk(child, receiver_name) {
            return true
        }
    }
    return false
}

fn free_method_matches_receiver_expr(expr ast.Expr, receiver_name string) bool {
    return match expr {
        ast.Ident { expr.name == receiver_name }
        ast.CastExpr { free_method_matches_receiver_expr(expr.expr, receiver_name) }
        ast.ParExpr { free_method_matches_receiver_expr(expr.expr, receiver_name) }
        else { false }
    }
}

fn (g &Gen) prefers_msvc_compatible_code() bool {
    return g.is_cc_msvc || g.pref.os == .windows
}

fn (mut g Gen) node_decl_fkey(node ast.FnDecl) string {
    if node.is_method && !node.name.contains('_T_') {
        if !node.receiver.typ.has_flag(.generic)
            && !g.type_has_unresolved_generic_parts(node.receiver.typ) {
            if structured_method := g.table.find_structured_receiver_method_with_types(node.receiver.typ,
                node.name)
            {
                if structured_method.method.receiver_type != node.receiver.typ {
                    if exact_method := g.receiver_exact_method_for_type(node.receiver.typ,
                        node.name)
                    {
                        if g.method_decl_fkey(exact_method) == node.fkey() {
                            return node.fkey()
                        }
                    }
                }
            }
        }
        receiver_sym := g.table.sym(node.receiver.typ)
        receiver_has_concrete_generics := match receiver_sym.info {
            ast.Struct, ast.Interface, ast.SumType {
                receiver_sym.info.concrete_types.len > 0 || receiver_sym.generic_types.len > 0
            }
            ast.GenericInst {
                true
            }
            else {
                false
            }
        }

        needs_generic_method_fkey := node.generic_names.len > 0 || node.ninstances > 0
            || node.receiver.typ.has_flag(.generic)
            || g.type_has_unresolved_generic_parts(node.receiver.typ)
            || receiver_has_concrete_generics
        if !needs_generic_method_fkey {
            return node.fkey()
        }
        resolved_fkey := g.resolve_method_decl_fkey_for_type(node.receiver.typ, node.name)
        if resolved_fkey != '' {
            $if trace_decl_fkey ? {
                if node.name in ['call_generic_fn', 'collect', 'next', 'next1', 'next2', 'next3',
                    'method', 'another_method'] {
                    eprintln('>>> node_decl_fkey resolved: ${node.name} | receiver: ${g.table.type_to_str(node.receiver.typ)} | fkey: ${resolved_fkey}')
                }
            }
            return resolved_fkey
        }
        if generic_method := g.matching_generic_file_method(node) {
            $if trace_decl_fkey ? {
                if node.name in ['call_generic_fn', 'collect', 'next', 'next1', 'next2', 'next3',
                    'method', 'another_method'] {
                    eprintln('>>> node_decl_fkey matched file generic: ${node.name} | receiver: ${g.table.type_to_str(node.receiver.typ)} | matched receiver: ${g.table.type_to_str(generic_method.receiver.typ)} | fkey: ${generic_method.fkey()}')
                }
            }
            return generic_method.fkey()
        }
    }
    return node.fkey()
}

fn (mut g Gen) method_receiver_signature(typ ast.Type) string {
    if typ == 0 {
        return ''
    }
    base_typ := g.table.unaliased_type(g.unwrap_generic(typ))
    sym := g.table.final_sym(base_typ)
    return '${sym.ngname}|${base_typ.nr_muls()}'
}

fn (mut g Gen) matching_generic_file_method(node ast.FnDecl) ?ast.FnDecl {
    if !node.is_method {
        return none
    }
    node_receiver_sig := g.method_receiver_signature(node.receiver.typ)
    if node_receiver_sig == '' {
        return none
    }
    for generic_fn in g.file.generic_fns {
        if !generic_fn.is_method || generic_fn.name != node.name {
            continue
        }
        $if trace_decl_fkey ? {
            if node.name in ['call_generic_fn', 'collect', 'next', 'next1', 'next2', 'next3',
                'method', 'another_method'] {
                eprintln('>>> matching_generic_file_method: ${node.name} | node receiver: ${g.table.type_to_str(node.receiver.typ)} | node sig: ${node_receiver_sig} | generic receiver: ${g.table.type_to_str(generic_fn.receiver.typ)} | generic sig: ${g.method_receiver_signature(generic_fn.receiver.typ)} | generic fkey: ${generic_fn.fkey()}')
            }
        }
        if g.method_receiver_signature(generic_fn.receiver.typ) == node_receiver_sig {
            return ast.FnDecl{
                ...*generic_fn
            }
        }
    }
    return none
}

fn (g &Gen) generic_file_fn_by_fkey(fkey string) ?ast.FnDecl {
    for generic_fn in g.file.generic_fns {
        if generic_fn.fkey() == fkey {
            return ast.FnDecl{
                ...*generic_fn
            }
        }
    }
    return none
}

// find_all_receiver_concrete_types finds all concrete type instantiations
// of the receiver's generic type by looking up GenericInst types in the type table.
// find_all_receiver_concrete_types finds all concrete type instantiations
// of the receiver's generic type by examining registered concrete types of
// sibling methods on the same receiver that have complete type sets.
fn (mut g Gen) find_all_receiver_concrete_types(node ast.FnDecl, receiver_generic_count int) [][]ast.Type {
    receiver_typ_int := int(node.receiver.typ)
    prefix := '${receiver_typ_int}.'
    mut result := [][]ast.Type{}
    mut seen := map[string]bool{}
    // Look through all registered method generic types on this receiver
    for fkey, type_sets in g.table.fn_generic_types {
        if !fkey.starts_with(prefix) {
            continue
        }
        for concrete_types in type_sets {
            if concrete_types.any(it.has_flag(.generic) || g.type_has_unresolved_generic_parts(it)) {
                continue
            }
            // We need sets that have both receiver + method generics
            if concrete_types.len > receiver_generic_count {
                receiver_part := concrete_types[..receiver_generic_count]
                key := receiver_part.str()
                if key !in seen {
                    seen[key] = true
                    result << receiver_part
                }
            }
        }
    }
    // Fallback: if no sibling methods have complete type sets, look for
    // concrete instantiations of the receiver type in the type table
    // (GenericInst types whose parent matches the receiver).
    if result.len == 0 {
        receiver_parent := node.receiver.typ.set_nr_muls(0).set_flag(.generic)
        receiver_parent_sym := g.table.sym(receiver_parent)
        receiver_base_name := receiver_parent_sym.name.all_before('<')
        for _, sym in g.table.type_symbols {
            if sym.info is ast.Struct {
                if sym.info.concrete_types.len == receiver_generic_count
                    && (sym.info.parent_type == receiver_parent
                    || (sym.info.parent_type != 0
                    && g.table.sym(sym.info.parent_type).name.all_before('<') == receiver_base_name)) {
                    cts := sym.info.concrete_types
                    if !cts.any(it.has_flag(.generic) || g.type_has_unresolved_generic_parts(it)) {
                        key := cts.str()
                        if key !in seen {
                            seen[key] = true
                            result << cts.clone()
                        }
                    }
                }
            }
        }
    }
    return result
}

fn (mut g Gen) effective_fn_generic_names(node ast.FnDecl) []string {
    if node.generic_names.len > 0 {
        return node.generic_names.clone()
    }
    if !node.is_method {
        return []string{}
    }
    resolved_fkey := g.node_decl_fkey(node)
    if generic_method := g.generic_file_fn_by_fkey(resolved_fkey) {
        if generic_method.generic_names.len > 0 {
            $if trace_decl_fkey ? {
                if node.name in ['call_generic_fn', 'collect', 'next', 'next1', 'next2', 'next3',
                    'method', 'another_method'] {
                    eprintln('>>> effective_fn_generic_names from file generic: ${node.name} | receiver: ${g.table.type_to_str(node.receiver.typ)} | generic_names: ${generic_method.generic_names}')
                }
            }
            return generic_method.generic_names.clone()
        }
        receiver_generic_names := g.table.generic_type_names(generic_method.receiver.typ)
        if receiver_generic_names.len > 0 {
            $if trace_decl_fkey ? {
                if node.name in ['call_generic_fn', 'collect', 'next', 'next1', 'next2', 'next3',
                    'method', 'another_method'] {
                    eprintln('>>> effective_fn_generic_names from generic receiver: ${node.name} | receiver: ${g.table.type_to_str(generic_method.receiver.typ)} | generic_names: ${receiver_generic_names}')
                }
            }
            return receiver_generic_names
        }
    }
    receiver_generic_names := g.table.generic_type_names(node.receiver.typ)
    if receiver_generic_names.len == 0 {
        return []string{}
    }
    if g.table.fn_generic_types[g.node_decl_fkey(node)].len > 0 {
        return receiver_generic_names
    }
    return []string{}
}

// method_concrete_types_for_name returns the concrete types for the generic
// name suffix in c_fn_name. For methods where cur_concrete_types includes
// merged receiver + method types that were synthesized in gen_fn_decl
// (because the checker only registered method-own types), strip the
// receiver's types from the suffix since they're already encoded in the
// receiver type name (e.g., Foo_T_string).
fn (mut g Gen) method_concrete_types_for_name(node &ast.FnDecl) []ast.Type {
    if !node.is_method || g.cur_concrete_types.len == 0 {
        return g.cur_concrete_types
    }
    receiver_generic_names := g.table.generic_type_names(node.receiver.typ)
    if receiver_generic_names.len == 0 || g.cur_concrete_types.len <= receiver_generic_names.len {
        return g.cur_concrete_types
    }
    // Check if the checker registered incomplete types (method-only) or
    // complete types (receiver + method). If the registered types are
    // already complete, don't strip anything.
    // Always use the full concrete types (receiver + method). The call site
    // is responsible for generating matching names via method_name_concrete_types.
    return g.cur_concrete_types
}

fn (mut g Gen) resolve_current_fn_generic_type(typ ast.Type) ast.Type {
    if typ == 0 {
        return 0
    }
    _, generic_names := g.current_fn_generic_params()
    if generic_names.len == 0 || g.cur_concrete_types.len == 0 {
        return g.unwrap_generic(typ)
    }
    concrete_types := g.cur_concrete_types.map(ast.mktyp(it))
    mut muttable := unsafe { &ast.Table(g.table) }
    if resolved := muttable.convert_generic_type(typ, generic_names, concrete_types) {
        return g.unwrap_generic(resolved)
    }
    return g.unwrap_generic(g.recheck_concrete_type(typ))
}

fn (mut g Gen) resolved_call_concrete_type(typ ast.Type) ast.Type {
    return ast.mktyp(g.resolve_current_fn_generic_type(typ))
}

fn (mut g Gen) receiver_concrete_types_for_type(typ ast.Type) []ast.Type {
    if typ == 0 {
        return []ast.Type{}
    }
    sym := g.table.sym(typ)
    match sym.info {
        ast.Struct, ast.Interface, ast.SumType {
            mut concrete_types := sym.info.concrete_types.clone()
            if concrete_types.len == 0 && sym.generic_types.len == sym.info.generic_types.len
                && sym.generic_types != sym.info.generic_types {
                concrete_types = sym.generic_types.clone()
            }
            return concrete_types.map(g.unwrap_generic(it))
        }
        ast.GenericInst {
            return sym.info.concrete_types.map(g.unwrap_generic(it))
        }
        else {
            return []ast.Type{}
        }
    }
}

fn (mut g Gen) method_receiver_generic_names(method ast.Fn) []string {
    if method.params.len == 0 {
        return []string{}
    }
    structured_receiver_generic_names :=
        g.table.structured_receiver_generic_pattern_names(method.params[0].typ)
    if structured_receiver_generic_names.len > 0 {
        return structured_receiver_generic_names
    }
    return g.table.generic_type_names(method.params[0].typ)
}

fn (mut g Gen) method_receiver_only_specialization_types(method ast.Fn, concrete_receiver_type ast.Type) []ast.Type {
    mut receiver_concrete_types := g.receiver_concrete_types_for_type(concrete_receiver_type)
    if receiver_concrete_types.len == 0 {
        receiver_concrete_types =
            g.receiver_concrete_types_for_type(g.recheck_concrete_type(concrete_receiver_type))
    }
    mut parent_method := ast.Fn{}
    _, parent_method = g.receiver_generic_call_context(concrete_receiver_type, method.name)
    if parent_method.params.len == 0 {
        _, parent_method = g.receiver_generic_call_context(g.recheck_concrete_type(concrete_receiver_type),
            method.name)
    }
    method_receiver_generic_names := if method.params.len > 0 {
        g.table.generic_type_names(method.params[0].typ)
    } else {
        []string{}
    }
    parent_receiver_generic_names := if parent_method.params.len > 0 {
        g.table.generic_type_names(parent_method.params[0].typ)
    } else {
        []string{}
    }
    full_method := if parent_method.generic_names.len > method.generic_names.len
        || (method_receiver_generic_names.len == 0 && parent_receiver_generic_names.len > 0) {
        parent_method
    } else {
        method
    }
    if receiver_concrete_types.len == 0 || full_method.params.len == 0 {
        return []ast.Type{}
    }
    receiver_generic_names := g.table.generic_type_names(full_method.params[0].typ)
    if receiver_generic_names.len == 0 {
        if receiver_concrete_types.len > 0
            && full_method.generic_names.len == receiver_concrete_types.len {
            return receiver_concrete_types.clone()
        }
        return []ast.Type{}
    }
    if full_method.generic_names.len == 0
        || (full_method.generic_names.len == receiver_generic_names.len
        && full_method.generic_names == receiver_generic_names) {
        return receiver_concrete_types.clone()
    }
    return []ast.Type{}
}

fn (mut g Gen) specialized_method_name_from_receiver(method ast.Fn, concrete_receiver_type ast.Type, base_name string) string {
    specialization_types := g.method_receiver_only_specialization_types(method,
        concrete_receiver_type)
    if specialization_types.len == 0 {
        return base_name
    }
    specialized_suffix := g.generic_fn_name(specialization_types, '')
    if specialized_suffix != '' && base_name.ends_with(specialized_suffix) {
        return base_name
    }
    return g.generic_fn_name(specialization_types, base_name)
}

fn (mut g Gen) specialized_method_name_from_receiver_context(method ast.Fn, receiver_concrete_types []ast.Type, parent_method ast.Fn, base_name string) string {
    if receiver_concrete_types.len == 0 || method.params.len == 0 {
        return base_name
    }
    method_receiver_generic_names := g.table.generic_type_names(method.params[0].typ)
    parent_receiver_generic_names := if parent_method.params.len > 0 {
        g.table.generic_type_names(parent_method.params[0].typ)
    } else {
        []string{}
    }
    full_method := if parent_method.generic_names.len > method.generic_names.len
        || (method_receiver_generic_names.len == 0 && parent_receiver_generic_names.len > 0) {
        parent_method
    } else {
        method
    }
    receiver_generic_names := g.table.generic_type_names(full_method.params[0].typ)
    if receiver_generic_names.len == 0 {
        if full_method.generic_names.len != receiver_concrete_types.len {
            return base_name
        }
    } else if full_method.generic_names.len > 0
        && (full_method.generic_names.len != receiver_generic_names.len
        || full_method.generic_names != receiver_generic_names) {
        return base_name
    }
    specialized_suffix := g.generic_fn_name(receiver_concrete_types, '')
    if specialized_suffix != '' && base_name.ends_with(specialized_suffix) {
        return base_name
    }
    return g.generic_fn_name(receiver_concrete_types, base_name)
}

fn (mut g Gen) recover_method_call_concrete_types_from_name(raw_method_name string, method_name string, receiver_type ast.Type, method_for_generics ast.Fn, parent_generic_method ast.Fn) []ast.Type {
    if raw_method_name == '' || method_name == ''
        || !raw_method_name.starts_with(method_name + '_T_') {
        return []ast.Type{}
    }
    method_receiver_generic_names := if method_for_generics.params.len > 0 {
        g.table.generic_type_names(method_for_generics.params[0].typ)
    } else {
        []string{}
    }
    parent_receiver_generic_names := if parent_generic_method.params.len > 0 {
        g.table.generic_type_names(parent_generic_method.params[0].typ)
    } else {
        []string{}
    }
    full_method := if
        parent_generic_method.generic_names.len > method_for_generics.generic_names.len
        || (method_receiver_generic_names.len == 0 && parent_receiver_generic_names.len > 0) {
        parent_generic_method
    } else {
        method_for_generics
    }
    mut full_fkey := g.resolve_method_decl_fkey_for_type(receiver_type, method_name)
    if full_fkey == '' {
        full_fkey = g.method_decl_fkey(full_method)
    }
    if full_fkey == '' {
        return []ast.Type{}
    }
    for candidate in g.table.fn_generic_types[full_fkey] {
        if candidate.any(it.has_flag(.generic) || g.type_has_unresolved_generic_parts(it)) {
            continue
        }
        name_concrete_types := candidate.map(g.unwrap_generic(it))
        if g.generic_fn_name(name_concrete_types, method_name) == raw_method_name {
            return candidate.map(g.unwrap_generic(it))
        }
    }
    return []ast.Type{}
}

fn (mut g Gen) method_name_concrete_types(full_fkey string, concrete_types []ast.Type, receiver_concrete_types []ast.Type) []ast.Type {
    if full_fkey == '' || concrete_types.len == 0 {
        return concrete_types.clone()
    }
    normalized_concrete_types := concrete_types.map(g.unwrap_generic(it))
    normalized_receiver_types := receiver_concrete_types.map(g.unwrap_generic(it))
    mut matching_partial_candidate := []ast.Type{}
    for candidate in g.table.fn_generic_types[full_fkey] {
        if candidate.any(it.has_flag(.generic) || g.type_has_unresolved_generic_parts(it)) {
            continue
        }
        normalized_candidate := candidate.map(g.unwrap_generic(it))
        if normalized_candidate == normalized_concrete_types {
            return normalized_candidate
        }
        if normalized_receiver_types.len > 0
            && normalized_candidate.len + normalized_receiver_types.len == normalized_concrete_types.len
            && normalized_concrete_types[..normalized_receiver_types.len] == normalized_receiver_types
            && normalized_concrete_types[normalized_receiver_types.len..] == normalized_candidate {
            // Return the full types (receiver + method) to match the function
            // definition which always uses complete types.
            return normalized_concrete_types
        }
        if normalized_candidate.len > normalized_concrete_types.len
            && normalized_candidate[..normalized_concrete_types.len] == normalized_concrete_types {
            if matching_partial_candidate.len == 0 {
                matching_partial_candidate = normalized_candidate.clone()
            } else if matching_partial_candidate != normalized_candidate {
                return normalized_concrete_types
            }
        }
    }
    if matching_partial_candidate.len > 0 {
        return matching_partial_candidate
    }
    return normalized_concrete_types
}

fn (mut g Gen) raw_method_name_concrete_types(raw_method_name string, method_name string, raw_concrete_types []ast.Type, receiver_concrete_types []ast.Type) []ast.Type {
    if raw_method_name == '' || method_name == '' || raw_concrete_types.len == 0
        || !raw_method_name.starts_with(method_name + '_T_') {
        return []ast.Type{}
    }
    mut resolved_raw_concrete_types := []ast.Type{}
    for concrete_type in raw_concrete_types {
        resolved_concrete_type := g.resolved_call_concrete_type(concrete_type)
        if resolved_concrete_type == 0 || resolved_concrete_type.has_flag(.generic)
            || g.type_has_unresolved_generic_parts(resolved_concrete_type) {
            return []ast.Type{}
        }
        resolved_raw_concrete_types << resolved_concrete_type
    }
    if g.generic_fn_name(resolved_raw_concrete_types, method_name) == raw_method_name {
        return resolved_raw_concrete_types
    }
    if receiver_concrete_types.len > 0
        && resolved_raw_concrete_types.len > receiver_concrete_types.len {
        method_only_types := resolved_raw_concrete_types[receiver_concrete_types.len..].clone()
        if g.generic_fn_name(method_only_types, method_name) == raw_method_name {
            return method_only_types
        }
    }
    if raw_concrete_types.any(it.has_flag(.generic) || g.type_has_unresolved_generic_parts(it)) {
        return resolved_raw_concrete_types
    }
    return []ast.Type{}
}

fn (g &Gen) raw_method_name_suffix(raw_method_name string, method_name string, generic_names []string) string {
    if raw_method_name == '' || method_name == ''
        || !raw_method_name.starts_with(method_name + '_T_') {
        return ''
    }
    suffix_tokens := raw_method_name[method_name.len + 3..].split('_').filter(it.len > 0)
    for suffix_token in suffix_tokens {
        if suffix_token in generic_names {
            return ''
        }
    }
    return raw_method_name[method_name.len..]
}

fn file_has_c_includes(file &ast.File) bool {
    if file == unsafe { nil } {
        return false
    }
    for stmt in file.stmts {
        if stmt is ast.HashStmt && stmt.kind in ['include', 'preinclude'] {
            return true
        }
    }
    return false
}

fn file_links_c_source(file &ast.File) bool {
    if file == unsafe { nil } {
        return false
    }
    for stmt in file.stmts {
        if stmt is ast.HashStmt && stmt.kind == 'flag' {
            if stmt.main.contains('.c ') || stmt.main.ends_with('.c') || stmt.main.contains('.cpp')
                || stmt.main.contains('.cc') || stmt.main.contains('.o ')
                || stmt.main.ends_with('.o') {
                return true
            }
        }
    }
    return false
}

fn (g &Gen) should_emit_c_extern_decl(node ast.FnDecl) bool {
    if node.language != .c || node.is_c_extern {
        return false
    }
    if node.source_file == unsafe { nil } {
        return false
    }
    if file_has_c_includes(node.source_file) {
        return false
    }
    if file_links_c_source(node.source_file) {
        return true
    }
    if node.mod in g.mods_with_c_libs && node.mod !in g.mods_with_c_includes {
        return true
    }
    if g.pref.os == .vinix && !node.source_file.path.starts_with(g.pref.vlib) {
        c_sym_name := node.name.after('.')
        if c_sym_name.starts_with('__builtin_') {
            return false
        }
        if c_sym_name in ['text_start', 'text_end', 'rodata_start', 'rodata_end', 'data_start',
            'data_end', 'interrupt_thunks'] {
            return false
        }
        return true
    }
    return false
}

fn (mut g Gen) ensure_extern_sig_type_decls(node ast.FnDecl) {
    g.ensure_extern_sig_type_decl(node.return_type)
    for param in node.params {
        g.ensure_extern_sig_type_decl(param.typ)
    }
}

fn (mut g Gen) ensure_extern_sig_type_decl(typ_ ast.Type) {
    if typ_ == 0 {
        return
    }
    typ := typ_.clear_option_and_result().set_nr_muls(0).clear_flags(.generic, .variadic)
    if typ == 0 {
        return
    }
    sym := g.table.sym(typ)
    if sym.idx in g.emitted_extern_sig_typedefs {
        return
    }
    g.emitted_extern_sig_typedefs[sym.idx] = true
    if sym.is_builtin || sym.name in ['byte', 'i32', 'C.FILE'] {
        return
    }
    match sym.info {
        ast.FnType {
            // A function-pointer parameter has its own params/return type, which
            // may also reference struct types that are otherwise unreferenced in V.
            g.ensure_extern_sig_type_decl(sym.info.func.return_type)
            for param in sym.info.func.params {
                g.ensure_extern_sig_type_decl(param.typ)
            }
            return
        }
        ast.Array {
            g.ensure_extern_sig_type_decl(sym.info.elem_type)
            return
        }
        ast.ArrayFixed {
            g.ensure_extern_sig_type_decl(sym.info.elem_type)
            return
        }
        ast.Map {
            g.ensure_extern_sig_type_decl(sym.info.key_type)
            g.ensure_extern_sig_type_decl(sym.info.value_type)
            return
        }
        ast.Alias {
            g.ensure_extern_sig_type_decl(sym.info.parent_type)
            return
        }
        else {}
    }

    if sym.info is ast.Struct {
        if sym.language == .c && sym.cname.starts_with('C__') && !sym.info.is_anon {
            // Empty `struct C.Foo {}` decls without a backing header (e.g. translated
            // code) get no struct typedef from `write_types`. Without a file-scope
            // forward decl, each prototype's `struct Foo*` introduces a prototype-
            // scoped tag, and clang rejects pairs of decls as `conflicting types`.
            c_struct_name := sym.cname[3..]
            if c_struct_name != 'va_list' {
                if sym.info.is_typedef {
                    g.typedefs.writeln('typedef struct ${c_struct_name} ${c_struct_name};')
                } else {
                    g.typedefs.writeln('struct ${c_struct_name};')
                }
            }
        } else if sym.idx !in g.table.used_features.used_syms {
            g.typedefs.writeln('typedef struct ${sym.cname} ${sym.cname};')
        }
    }
}

fn (mut g Gen) is_used_by_main(node ast.FnDecl) bool {
    $if trace_unused_by_main ? {
        defer(fn) {
            used_by_main := $res()
            if !used_by_main {
                fkey := node.fkey()
                println('> trace_unused_by_main: mod: ${node.mod} | ${node.name} | fkey: ${fkey} | line_nr: ${node.pos.line_nr}')
            }
        }
    }
    if g.should_emit_c_extern_decl(node) {
        return true
    }
    if node.is_c_extern {
        return true
    }
    if node.is_method && node.name in ['[]', '[]='] {
        return true
    }
    if node.is_test && node.name.all_after_last('.') in ['before_each', 'after_each'] {
        return true
    }
    if node.mod == 'builtin' && node.name in ['print', 'println', 'eprint', 'eprintln'] {
        return true
    }
    mut is_used_by_main := true
    if g.pref.skip_unused {
        if node.is_markused {
            // TODO for some reason markused walker doesn't set used_fns[key] true for
            // [markused] fndecls
            return true
        }
        fkey := g.node_decl_fkey(node)
        is_used_by_main = g.table.used_features.used_fns[fkey]
        if !is_used_by_main && node.is_method && !node.receiver.typ.has_flag(.generic)
            && !g.type_has_unresolved_generic_parts(node.receiver.typ) {
            if structured_method := g.table.find_structured_receiver_method_with_types(node.receiver.typ,
                node.name)
            {
                if structured_method.method.receiver_type != node.receiver.typ {
                    if exact_method := g.receiver_exact_method_for_type(node.receiver.typ,
                        node.name)
                    {
                        is_used_by_main = g.method_decl_fkey(exact_method) == node.fkey()
                    }
                }
            }
        }
        if !is_used_by_main && g.effective_fn_generic_names(node).len > 0
            && g.table.fn_generic_types[fkey].len > 0 {
            is_used_by_main = true
        }
        if !is_used_by_main && node.generic_names.len == 0 {
            recovered_generic_names, recovered_concrete_types :=
                g.recover_specialized_generic_context_for(node.name)
            if recovered_generic_names.len > 0
                && recovered_generic_names.len == recovered_concrete_types.len {
                for generic_fn in g.file.generic_fns {
                    if generic_fn.generic_names.len == 0 {
                        continue
                    }
                    for base_name in [generic_fn.name, generic_fn.fkey()] {
                        if g.generic_fn_name(recovered_concrete_types, base_name) == node.name {
                            is_used_by_main = g.table.used_features.used_fns[generic_fn.fkey()]
                            if is_used_by_main {
                                break
                            }
                        }
                    }
                    if is_used_by_main {
                        break
                    }
                }
            }
            if !is_used_by_main && node.name.contains('_T_') {
                is_used_by_main = true
            }
        }
        $if trace_skip_unused_fns ? {
            println('> is_used_by_main: ${is_used_by_main} | node.name: ${node.name} | fkey: ${fkey} | node.is_method: ${node.is_method}')
        }
        if !is_used_by_main && node.is_method {
            receiver_type := g.table.final_type(node.receiver.typ.set_nr_muls(0))
            for isym in g.table.type_symbols {
                if isym.kind != .interface || isym.info !is ast.Interface {
                    continue
                }
                if isym.idx !in g.table.used_features.used_syms {
                    continue
                }
                inter_info := isym.info as ast.Interface
                impl_types := inter_info.implementor_types(true)
                if receiver_type !in impl_types {
                    continue
                }
                mut interface_requires_method := false
                if interface_method := isym.find_method(node.name) {
                    interface_requires_method = interface_method.no_body
                } else if interface_method := isym.find_method_with_generic_parent(node.name) {
                    interface_requires_method = interface_method.no_body
                }
                if interface_requires_method {
                    is_used_by_main = true
                    break
                }
            }
        }
        if !is_used_by_main {
            $if trace_skip_unused_fns_in_c_code ? {
                g.writeln('// trace_skip_unused_fns_in_c_code, ${node.name}, fkey: ${fkey}')
            }
        }
    } else {
        $if trace_skip_unused_fns_in_c_code ? {
            g.writeln('// trace_skip_unused_fns_in_c_code, ${node.name}, fkey: ${node.fkey()}')
        }
    }
    return is_used_by_main
}

fn (mut g Gen) fn_decl(node ast.FnDecl) {
    $if trace_cgen_fn_decl ? {
        eprintln('>   g.tid: ${g.tid} | g.fid: ${g.fid:3} | g.file.path: ${g.file.path} | fn_decl: ${node.name}')
    }
    if node.should_be_skipped {
        return
    }
    if node.is_test {
        g.test_function_names << node.name
    }
    effective_generic_names := g.effective_fn_generic_names(node)
    if node.ninstances == 0 && effective_generic_names.len > 0
        && g.table.fn_generic_types[g.node_decl_fkey(node)].len == 0 {
        $if trace_generics ? {
            eprintln('skipping generic fn with no concrete instances: ${node.mod} ${node.name}')
        }
        return
    }
    if !g.is_used_by_main(node) {
        return
    }
    if g.is_builtin_mod && g.pref.gc_mode == .boehm_leak && node.kind == .malloc {
        g.definitions.write_string('#define builtin___v_malloc GC_MALLOC\n')
        return
    }

    if g.pref.parallel_cc {
        if node.is_anon {
            // g.write('static ')
            // g.definitions.write_string('static ')
        }
        if !node.is_anon {
            g.out_fn_start_pos << g.out.len
        }
    }
    prev_is_direct_array_access := g.is_direct_array_access
    g.is_direct_array_access = node.is_direct_arr || g.pref.no_bounds_checking
    defer {
        g.is_direct_array_access = prev_is_direct_array_access
    }

    // handle `@[ignore_overflow] fn abc() {}` and -check-overflow :
    prev_do_int_overflow_checks := g.do_int_overflow_checks
    g.do_int_overflow_checks = g.pref.is_check_overflow && !g.is_builtin_overflow_mod
        && !node.is_ignore_overflow
    defer {
        g.do_int_overflow_checks = prev_do_int_overflow_checks
    }

    // handle `@[c_extern] fn C.some_name() int` declarations:
    old_inside_c_extern := g.inside_c_extern
    defer {
        g.inside_c_extern = old_inside_c_extern
    }
    if node.language == .c && (node.is_c_extern || g.should_emit_c_extern_decl(node)) {
        g.inside_c_extern = true
        if g.pref.skip_unused {
            g.ensure_extern_sig_type_decls(node)
        }
    } else if g.pref.skip_unused && node.no_body && node.language == .v {
        // Body-less V fns (e.g. `@[c: 'NAME'] fn foo()`) emit a forward decl whose
        // signature may reference opaque C structs that `write_types` skips.
        g.ensure_extern_sig_type_decls(node)
    }

    g.gen_attrs(node.attrs)
    mut skip := false
    pos := g.out.len
    defs_pos := g.definitions.len
    should_bundle_module := util.should_bundle_module(node.mod)
    if g.pref.build_mode == .build_module {
        // TODO: true for not just "builtin"
        // TODO: clean this up
        mod := if g.is_builtin_mod { 'builtin' } else { node.name.all_before_last('.') }
        module_built_short := g.module_built.all_after_last('/').all_after_last('.')
        // for now dont skip generic functions as they are being marked as static
        // when -usecache is enabled, until a better solution is implemented.
        if ((mod != g.module_built && node.mod != g.module_built && node.mod != module_built_short)
            || should_bundle_module) && node.generic_names.len == 0 {
            // Skip functions that don't have to be generated for this module.
            // println('skip bm ${node.name} mod=${node.mod} module_built=${g.module_built}')
            skip = true
        }
        if g.is_builtin_mod && g.module_built == 'builtin' && node.mod == 'builtin' {
            skip = false
        }
        if !skip && g.pref.is_verbose {
            println('build module `${g.module_built}` fn `${node.name}`')
        }
    }
    if g.pref.use_cache {
        // We are using prebuilt modules, we do not need to generate
        // their functions in main.c.
        if node.mod != 'main' && node.mod != 'help' && !should_bundle_module && !g.pref.is_test
            && node.generic_names.len == 0 {
            skip = true
        }
    }
    keep_fn_decl := g.fn_decl
    unsafe {
        g.fn_decl = &node
    }
    if node.is_main {
        g.has_main = true
    }
    // TODO: PERF remove this from here
    is_backtrace := node.name.starts_with('backtrace')
        && node.name in ['backtrace_symbols', 'backtrace', 'backtrace_symbols_fd']
    if is_backtrace {
        g.write('\n#ifndef __cplusplus\n')
    }
    g.gen_fn_decl(node, skip)
    if is_backtrace {
        g.write('\n#endif\n')
    }
    g.fn_decl = keep_fn_decl
    if skip {
        g.go_back_to(pos)
        if g.pref.build_mode != .build_module && !g.pref.use_cache {
            g.definitions.go_back_to(defs_pos)
        }
    }
    if !g.pref.skip_unused {
        if node.language != .c {
            g.writeln('')
        }
    }
    // Write the next function into another parallel C file
    // g.out_idx++
    // if g.out_idx >= g.out_parallel.len {
    // g.out_idx = 0
    //}
}

fn (mut g Gen) post_process_generic_fns_for_files(files []&ast.File) {
    old_file := g.file
    old_fid := g.fid
    old_cur_concrete_types := g.cur_concrete_types.clone()
    mut emitted_generic_specializations := map[string]bool{}
    for {
        mut emitted_this_round := false
        for fid, file in files {
            g.fid = fid
            g.file = file
            for generic_fn in file.generic_fns {
                if generic_fn.is_anon {
                    continue
                }
                effective_generic_names := g.effective_fn_generic_names(*generic_fn)
                if effective_generic_names.len == 0 {
                    continue
                }
                fkey := g.node_decl_fkey(*generic_fn)
                generic_types_by_fn := g.table.fn_generic_types[fkey].clone()
                if generic_types_by_fn.len == 0 {
                    continue
                }
                mut receiver_generic_names := []string{}
                mut all_receiver_cts := [][]ast.Type{}
                if generic_fn.is_method {
                    receiver_generic_names = g.table.generic_type_names(generic_fn.receiver.typ)
                    if receiver_generic_names.len > 0
                        && receiver_generic_names.len < effective_generic_names.len {
                        all_receiver_cts = g.find_all_receiver_concrete_types(*generic_fn,
                            receiver_generic_names.len)
                    }
                }
                for concrete_types in generic_types_by_fn {
                    if concrete_types.any(it.has_flag(.generic)
                        || g.type_has_unresolved_generic_parts(it))
                    {
                        continue
                    }
                    mut pending_specializations := [][]ast.Type{}
                    if concrete_types.len == effective_generic_names.len {
                        pending_specializations << concrete_types.clone()
                    } else if concrete_types.len < effective_generic_names.len
                        && all_receiver_cts.len > 0
                        && concrete_types.len + receiver_generic_names.len == effective_generic_names.len {
                        for receiver_cts in all_receiver_cts {
                            mut merged := receiver_cts.clone()
                            merged << concrete_types
                            pending_specializations << merged
                        }
                    }
                    for concrete_specialization in pending_specializations {
                        specialization_key := g.generic_fn_name(concrete_specialization, fkey)
                        if specialization_key in emitted_generic_specializations {
                            continue
                        }
                        emitted_generic_specializations[specialization_key] = true
                        g.cur_concrete_types = concrete_specialization.clone()
                        g.fn_decl(*generic_fn)
                        emitted_this_round = true
                    }
                }
            }
        }
        if !emitted_this_round {
            break
        }
        g.cur_concrete_types = []
    }
    g.cur_concrete_types = old_cur_concrete_types
    g.file = old_file
    g.fid = old_fid
}

fn (mut g Gen) gen_fn_decl(node &ast.FnDecl, skip bool) {
    $if trace_cgen_gen_fn_decl ? {
        eprintln('>   g.tid: ${g.tid} | g.fid: ${g.fid:3} | g.file.path: ${g.file.path} | gen_fn_decl: ${node.name} | skip: ${skip}')
    }
    // TODO: For some reason, build fails with autofree with this line
    // as it's only informative, comment it for now
    // g.gen_attrs(it.attrs)
    if node.language == .c && !g.inside_c_extern {
        return
    }
    c_sym_name := node.name.all_after_first('C__').all_after_first('C.')
    if node.language == .c && c_sym_name in ['va_start', 'va_arg', 'va_end', 'va_copy'] {
        return
    }
    old_is_vlines_enabled := g.is_vlines_enabled
    g.is_vlines_enabled = true
    defer {
        g.is_vlines_enabled = old_is_vlines_enabled
    }
    function_defer_stmts := collect_function_defer_stmts(node)

    tmp_defer_vars := g.defer_vars // must be here because of workflow
    if g.anon_fn == unsafe { nil } {
        g.defer_vars = []string{}
    } else {
        if function_defer_stmts.len > 0 {
            g.defer_vars = []string{}
            defer(fn) {
                g.defer_vars = tmp_defer_vars
            }
        }
    }
    // Skip [if xxx] if xxx is not defined
    /*
    for attr in node.attrs {
        if !attr.is_comptime_define {
            continue
        }
        if attr.name !in g.pref.compile_defines_all {
            // println('skipping [if]')
            return
        }
    }
    */

    g.returned_var_names.clear()
    old_g_autofree := g.is_autofree
    if node.is_manualfree {
        g.is_autofree = false
    }
    defer {
        g.is_autofree = old_g_autofree
    }
    effective_generic_names := g.effective_fn_generic_names(*node)
    if effective_generic_names.len > 0 && g.cur_concrete_types.len == 0 {
        return
    }
    // For methods with their own generics (e.g. fn (c Calc[S]) next[T](input T))
    // where cur_concrete_types only contains receiver generics (S=TypeA),
    // skip if cur_concrete_types doesn't match the expected number of generic names.
    if effective_generic_names.len > 0 && g.cur_concrete_types.len > 0
        && g.cur_concrete_types.len != effective_generic_names.len {
        return
    }
    cur_fn_save := g.cur_fn
    cur_concrete_types_save := g.cur_concrete_types.clone()
    defer {
        g.cur_fn = cur_fn_save
        g.cur_concrete_types = cur_concrete_types_save
        g.clear_type_resolution_caches()
    }
    mut effective_cur_fn := *node
    if g.cur_concrete_types.len > 0 && effective_generic_names.len == g.cur_concrete_types.len
        && effective_cur_fn.generic_names != effective_generic_names {
        effective_cur_fn = ast.FnDecl{
            ...effective_cur_fn
            generic_names: effective_generic_names.clone()
        }
    }
    if node.generic_names.len == 0 && g.cur_concrete_types.len == 0
        && (!node.is_method || node.receiver.typ.has_flag(.generic)
        || node.name.contains('_T_')) {
        recovered_generic_names, recovered_concrete_types :=
            g.recover_specialized_generic_context_for(node.name)
        if recovered_generic_names.len > 0
            && recovered_generic_names.len == recovered_concrete_types.len {
            effective_cur_fn = ast.FnDecl{
                ...*node
                generic_names: recovered_generic_names.clone()
            }
            g.cur_concrete_types = recovered_concrete_types.clone()
        }
    }
    unsafe {
        // TODO: remove unsafe
        g.cur_fn = &effective_cur_fn
    }
    g.clear_type_resolution_caches()
    g.refresh_current_generic_fn_scope_vars(g.cur_fn)
    fn_start_pos := g.out.len
    is_closure := node.scope.has_inherited_vars()
    mut cur_closure_ctx := ''
    if is_closure {
        cur_closure_ctx = g.closure_ctx(node)
        // declare the struct before its implementation
        g.definitions.write_string(cur_closure_ctx)
        g.definitions.writeln(';')
    }

    g.write_v_source_line_info_stmt(node)
    fn_attrs := g.write_fn_attrs(node.attrs)
    // Live
    is_livefn := node.attrs.contains('live')
    is_livemain := g.pref.is_livemain && is_livefn
    is_liveshared := g.pref.is_liveshared && is_livefn
    is_livemode := g.pref.is_livemain || g.pref.is_liveshared
    is_live_wrap := is_livefn && is_livemode
    if is_livefn && !is_livemode {
        eprintln('INFO: compile with `v -live ${g.pref.path} `, if you want to use the @[live] function ${node.name} .')
    }

    mut name := g.c_fn_name(node)
    type_name := g.ret_styp(g.unwrap_generic(node.return_type))
    // Live functions are protected by a mutex, because otherwise they
    // can be changed by the live reload thread, *while* they are
    // running, with unpredictable results (usually just crashing).
    // For this purpose, the actual body of the live function,
    // is put under a non publicly accessible function, that is prefixed
    // with 'impl_live_' .
    if is_livemode {
        if is_livefn {
            g.hotcode_fn_names << name
        }
        g.hotcode_fpaths << g.file.path
    }
    mut impl_fn_name := name
    if is_live_wrap {
        impl_fn_name = 'impl_live_${name}'
    }
    last_fn_c_name_save := g.last_fn_c_name
    defer {
        g.last_fn_c_name = last_fn_c_name_save
    }
    g.last_fn_c_name = impl_fn_name

    if !g.inside_c_extern && node.trace_fns.len > 0 {
        for trace_fn, call_fn in node.trace_fns {
            if trace_fn in g.trace_fn_definitions {
                continue
            }
            trace_fn_ret_type := g.styp(call_fn.return_type)

            g.write('VV_LOC ${trace_fn_ret_type} ${c_name(trace_fn)}(')
            g.definitions.write_string('VV_LOC ${trace_fn_ret_type} ${c_name(trace_fn)}(')

            mut trace_call_args := []string{}
            if call_fn.is_fn_var {
                sig := g.fn_var_signature(ast.void_type, call_fn.func.return_type,
                    call_fn.func.params.map(it.typ), call_fn.name)
                g.write(sig)
                g.definitions.write_string(sig)
                if call_fn.func.params.len > 0 {
                    g.write(', ')
                    g.definitions.write_string(', ')
                    trace_call_args, _, _ = g.fn_decl_params(call_fn.func.params, unsafe { nil },
                        call_fn.func.is_variadic, call_fn.func.is_c_variadic)
                }
            } else {
                trace_call_args, _, _ = g.fn_decl_params(call_fn.func.params, unsafe { nil },
                    call_fn.func.is_variadic, call_fn.func.is_c_variadic)
            }

            g.writeln(') {')
            g.definitions.write_string(');\n')

            orig_fn_args := trace_call_args.join(', ')
            add_trace_hook := g.pref.is_trace
                && call_fn.name !in ['v.debug.add_after_call', 'v.debug.add_before_call', 'v.debug.remove_after_call', 'v.debug.remove_before_call']
            if g.pref.is_callstack {
                if g.cur_fn.is_method || g.cur_fn.is_static_type_method {
                    g.writeln('\tbuiltin__array_push((array*)&g_callstack, _MOV((v__debug__FnTrace[]){ ((v__debug__FnTrace){.name = _S("${g.table.type_to_str(g.cur_fn.receiver.typ)}.${g.cur_fn.name.all_after_last('__static__')}"),.file = _S("${call_fn.file}"),.line = ${call_fn.line},}) }));')
                } else {
                    g.writeln('\tbuiltin__array_push((array*)&g_callstack, _MOV((v__debug__FnTrace[]){ ((v__debug__FnTrace){.name = _S("${g.cur_fn.name}"),.file = _S("${call_fn.file}"),.line = ${call_fn.line},}) }));')
                }
            }
            mut method_name := c_name(call_fn.name)
            if call_fn.name.contains('_') {
                parts := call_fn.name.split('_')
                if parts.len >= 2 {
                    receiver_type_name := parts[0]
                    if resolved_sym := g.table.find_sym(receiver_type_name) {
                        if resolved_sym.is_builtin() {
                            method_name = 'builtin__${method_name}'
                        }
                    }
                }
            }
            if call_fn.return_type == 0 || call_fn.return_type == ast.void_type {
                if add_trace_hook {
                    g.writeln('\tif (!g_trace.in_hook) {')
                    g.writeln('\t\tv__debug__before_call_hook(_S("${call_fn.name}"));')
                    g.writeln('\t}')
                }
                g.writeln('\t${method_name}(${orig_fn_args});')
                if add_trace_hook {
                    g.writeln('\tif (!g_trace.in_hook) {')
                    g.writeln('\t\tv__debug__after_call_hook(_S("${call_fn.name}"));')
                    g.writeln('\t}')
                }
                if g.pref.is_callstack {
                    g.writeln('\tbuiltin__array_pop((array*)&g_callstack);')
                }
            } else {
                if add_trace_hook {
                    g.writeln('\tif (!g_trace.in_hook) {')
                    g.writeln('\t\tv__debug__before_call_hook(_S("${call_fn.name}"));')
                    g.writeln('\t}')
                }
                g.writeln('\t${g.styp(call_fn.return_type)} ret = ${method_name}(${orig_fn_args});')
                if g.pref.is_callstack {
                    g.writeln('\tbuiltin__array_pop((array*)&g_callstack);')
                }
                if add_trace_hook {
                    g.writeln('\tif (!g_trace.in_hook) {')
                    g.writeln('\t\tv__debug__after_call_hook(_S("${call_fn.name}"));')
                    g.writeln('\t}')
                }
                g.writeln('\treturn ret;')
            }
            g.writeln2('}', '')
            g.trace_fn_definitions << trace_fn
        }
    }

    if is_live_wrap {
        if is_livemain {
            g.definitions.write_string('${type_name} (* ${impl_fn_name})(')
            g.write('${type_name} no_impl_${name}(')
        }
        if is_liveshared {
            if g.pref.os == .windows {
                g.export_funcs << impl_fn_name
                g.definitions.write_string('VV_EXP ${type_name} ${impl_fn_name}(')
                g.write('VV_EXP ${type_name} ${impl_fn_name}(')
            } else {
                g.definitions.write_string('${type_name} ${impl_fn_name}(')
                g.write('${type_name} ${impl_fn_name}(')
            }
        }
    } else if g.inside_c_extern {
        extern_name := name.all_after_first('C__')
        // Guard with #ifndef so the declaration is skipped when the C symbol
        // is actually a preprocessor macro (e.g. WIFSTOPPED from <sys/wait.h>).
        g.definitions.writeln('#ifndef ${extern_name}')
        c_extern_fn_header := 'extern ${type_name} ${fn_attrs}${extern_name}('
        g.definitions.write_string(c_extern_fn_header)
    } else {
        if !(node.is_pub || g.pref.is_debug) {
            // Private functions need to marked as static so that they are not exportable in the
            // binaries
            if g.pref.build_mode != .build_module && !g.pref.use_cache {
                // If we are building vlib/builtin, we need all private functions like array_get
                // to be public, so that all V programs can access them.
                if !(node.is_anon && g.pref.parallel_cc) {
                    g.write('VV_LOC ')
                    // g.definitions.write_string('${g.static_modifier} VV_LOC ')
                    g.definitions.write_string('VV_LOC ')
                }
            }
        }
        // as a temp solution generic functions are marked static
        // when -usecache is enabled to fix duplicate symbols with clang
        // TODO: implement a better sulution
        needs_object_local_linkage := g.should_use_object_local_linkage(node.mod)
            && (node.is_pub || g.pref.is_debug)
        visibility_kw := if needs_object_local_linkage {
            'static '
        } else if g.cur_concrete_types.len > 0
            && (g.pref.build_mode == .build_module || g.pref.use_cache) {
            'static '
        } else {
            ''
        }
        fn_header := '${visibility_kw}${type_name} ${fn_attrs}${name}('
        g.definitions.write_string(fn_header)
        g.write(fn_header)
    }
    arg_start_pos := g.out.len
    is_c_variadic := node.is_c_variadic || (node.language == .c && node.is_variadic)
    fargs, fargtypes, heap_promoted := g.fn_decl_params(node.params, node.scope, node.is_variadic,
        is_c_variadic)
    if is_closure {
        g.nr_closures++
        if g.pref.no_closures {
            g.error('a closure was generated for function', node.pos)
        }
    }
    arg_str := g.out.after(arg_start_pos)
    if node.no_body || ((g.pref.use_cache && g.pref.build_mode != .build_module) && node.is_builtin
        && !g.pref.is_test) || skip {
        // Just a function header. Builtin function bodies are defined in builtin.o
        g.definitions.writeln(');') // NO BODY')
        if g.inside_c_extern {
            g.definitions.writeln('#endif')
        } else {
            g.writeln(');')
        }
        return
    }
    if node.params.len == 0 {
        g.definitions.write_string('void')
    }
    if attr := node.attrs.find_first('_linker_section') {
        g.definitions.writeln(') __attribute__ ((section ("${attr.arg}")));')
    } else {
        g.definitions.writeln(');')
    }
    g.writeln(') {')
    if is_closure {
        g.writeln('${cur_closure_ctx}* ${closure_ctx} = g_closure.closure_get_data();')
    }
    for i, is_promoted in heap_promoted {
        if is_promoted {
            g.writeln('${fargtypes[i]}* ${fargs[i]} = HEAP(${fargtypes[i]}, _v_toheap_${fargs[i]});')
        }
    }
    g.indent++
    for defer_stmt in function_defer_stmts {
        if defer_stmt.mode != .function {
            continue
        }
        g.writeln('bool ${g.defer_flag_var(defer_stmt)} = false;')
        for var in defer_stmt.defer_vars {
            if var.name in fargs || var.kind == .constant {
                continue
            }
            if var.kind == .variable {
                if var.name !in g.defer_vars {
                    g.defer_vars << var.name
                    mut deref := ''
                    if v := var.scope.find_var(var.name) {
                        if v.is_auto_heap {
                            deref = '*'
                        }
                    }
                    info := var.obj as ast.Var
                    if g.table.sym(info.typ).kind != .function {
                        if info.is_static {
                            g.write('static ')
                        }
                        if info.is_volatile {
                            g.write('volatile ')
                        }
                        decl_typ := if deref == '*' {
                            info.typ.ref()
                        } else {
                            info.typ
                        }
                        default_expr := g.type_default(decl_typ)
                        if g.type_default_vars.len > 0 {
                            for decl in g.type_default_vars.str().trim_right('\n').split_into_lines() {
                                g.writeln(decl)
                            }
                            g.type_default_vars.clear()
                        }
                        g.writeln('${g.styp(info.typ)}${deref} ${c_name(var.name)} = ${default_expr};')
                    }
                }
            }
        }
    }
    g.indent--
    if is_live_wrap {
        // The live function just calls its implementation dual, while ensuring
        // that the call is wrapped by the mutex lock & unlock calls.
        // Adding the mutex lock/unlock inside the body of the implementation
        // function is not reliable, because the implementation function can do
        // an early exit, which will leave the mutex locked.
        live_mutex_ptr_type := if g.pref.os == .windows {
            'HANDLE*'
        } else {
            'pthread_mutex_t*'
        }
        mut fn_args_list := []string{}
        for ia, fa in fargs {
            fn_args_list << '${fargtypes[ia]} ${fa}'
        }
        mut live_fncall := '${impl_fn_name}(' + fargs.join(', ') + ');'
        mut live_fnreturn := ''
        if type_name != 'void' {
            live_fncall = '${type_name} res = ${live_fncall}'
            live_fnreturn = 'return res;'
        }
        if is_livemain {
            g.definitions.writeln('${type_name} no_impl_${name}(' + fn_args_list.join(', ') + ');')
        }
        g.definitions.writeln('${type_name} ${name}(' + fn_args_list.join(', ') + ');')
        g.hotcode_definitions.writeln('${type_name} ${name}(' + fn_args_list.join(', ') + '){')
        g.hotcode_definitions.writeln('  ${live_mutex_ptr_type} live_fn_mutex_ptr = v_live_fn_mutex_ptr();')
        g.hotcode_definitions.writeln('  pthread_mutex_lock(live_fn_mutex_ptr);')
        g.hotcode_definitions.writeln('  ${live_fncall}')
        g.hotcode_definitions.writeln('  pthread_mutex_unlock(live_fn_mutex_ptr);')
        g.hotcode_definitions.writeln('  ${live_fnreturn}')
        g.hotcode_definitions.writeln('}')
    }
    // Profiling mode? Start counting at the beginning of the function (save current time).
    if g.pref.is_prof && g.pref.build_mode != .build_module {
        g.profile_fn(node)
    }
    // we could be in an anon fn so save outer fn defer stmts
    prev_defer_stmts := g.defer_stmts
    g.defer_stmts = []
    ctmp := g.tmp_count
    g.tmp_count = 0
    defer {
        g.tmp_count = ctmp
    }
    prev_inside_ternary := g.inside_ternary
    g.inside_ternary = 0
    prev_indent := g.indent
    g.indent = 0
    defer {
        g.indent = prev_indent
    }
    g.stmts(node.stmts)
    g.inside_ternary = prev_inside_ternary
    if node.is_noreturn {
        g.writeln('\twhile(1);')
    }
    // clear g.fn_mut_arg_names

    if !node.has_return {
        g.write_defer_stmts_when_needed(node.scope, false, node.name_pos)
    }
    if node.is_anon {
        g.defer_stmts = prev_defer_stmts
    } else {
        g.defer_stmts = []
    }
    if node.return_type != ast.void_type && node.stmts.len > 0 && node.stmts.last() !is ast.Return
        && !node.attrs.contains('_naked') {
        default_expr := g.type_default(node.return_type)
        // TODO: perf?
        if default_expr == '{0}' {
            g.writeln('\treturn (${type_name})${default_expr};')
        } else {
            g.writeln('\treturn ${default_expr};')
        }
    }
    g.writeln('}')
    if g.pref.printfn_list.len > 0 && g.last_fn_c_name in g.pref.printfn_list {
        println(g.out.after(fn_start_pos))
    }
    weak := if node.is_weak { 'VWEAK ' } else { '' }
    for attr in node.attrs {
        if attr.name == 'export' {
            g.writeln('// export alias: ${attr.arg} -> ${name}')
            g.export_funcs << attr.arg
            export_alias := '${weak}${type_name} ${fn_attrs}${attr.arg}(${arg_str})'
            g.definitions.writeln('VV_EXP ${export_alias}; // exported fn ${node.name}')
            g.writeln('${export_alias} {')
            if !g.pref.is_shared && 'no_main' in g.table.modules {
                g.writeln('\t_vno_main_init_caller();')
            }
            g.write2('\treturn ${name}(', fargs.join(', '))
            g.writeln2(');', '}')
        }
    }
}

fn (mut g Gen) c_fn_name(node &ast.FnDecl) string {
    mut name := node.name
    if name in ['+', '-', '*', '**', '/', '%', '<', '==', '[]', '[]='] {
        name = util.replace_op(name)
    }
    if node.is_method {
        unwrapped_rec_typ := g.unwrap_generic(node.receiver.typ)
        name = g.cc_type(unwrapped_rec_typ, false) + '_' + name
        receiver_sym := g.table.sym(unwrapped_rec_typ)
        if receiver_sym.is_builtin() {
            name = 'builtin__${name}'
        }
        if receiver_sym.kind == .placeholder {
            name = name.replace_each(c_fn_name_escape_seq)
        }
    }
    if node.is_anon && g.anon_fn != unsafe { nil } && g.anon_fn.has_ct_var {
        name = '${name}_${g.comptime.comptime_loop_id}'
    }
    if node.language == .c {
        name = util.no_dots(name)
    } else {
        name = c_fn_name(name)
    }
    if !node.is_method && node.mod == 'builtin' && !name.starts_with('builtin__') {
        name = 'builtin__${name}'
    }

    if node.generic_names.len > 0 {
        name = g.generic_fn_name(g.method_concrete_types_for_name(node), name)
        name = name.replace_each(c_fn_name_escape_seq)
    }

    if g.pref.translated || g.file.is_translated || node.is_file_translated {
        if cattr := node.attrs.find_first('c') {
            // This fixes unknown symbols errors when building separate .c => .v files into .o files
            // example:
            // @[c: 'P_TryMove'] fn p_trymove(thing &Mobj_t, x int, y int) bool
            // translates to:
            // bool P_TryMove(main__Mobj_t* thing, int x, int y);
            // In fn_call every time `p_trymove` is called, `P_TryMove` will be generated instead.
            name = cattr.arg
        }
    }
    return name
}

const closure_ctx = '_V_closure_ctx'

fn (g &Gen) anon_fn_generic_names(generic_names []string) []string {
    if g.cur_fn == unsafe { nil } || g.cur_fn.generic_names.len == 0
        || g.cur_concrete_types.len == 0 {
        return generic_names.clone()
    }
    mut names := g.cur_fn.generic_names.clone()
    for generic_name in generic_names {
        if generic_name !in names {
            names << generic_name
        }
    }
    return names
}

fn (mut g Gen) gen_closure_fn_name(node ast.AnonFn) string {
    mut fn_name := node.decl.name
    if g.anon_fn_generic_names(node.decl.generic_names).len > 0 {
        fn_name = g.generic_fn_name(g.cur_concrete_types, fn_name)
    }
    if node.has_ct_var {
        fn_name += '_${g.comptime.comptime_loop_id}'
    }
    return fn_name
}

fn (mut g Gen) c_call_alias_signature(node ast.CallExpr, name string) string {
    ret_styp := g.styp(node.return_type)
    mut sig := '${ret_styp} (*${name})('
    if node.args.len == 0 {
        if !node.is_c_variadic {
            sig += 'void'
        }
    } else {
        for i, arg in node.args {
            arg_typ := if arg.typ != 0 {
                arg.typ
            } else if i < node.expected_arg_types.len {
                node.expected_arg_types[i]
            } else {
                ast.voidptr_type
            }
            sig += g.styp(arg_typ)
            if i < node.args.len - 1 || node.is_c_variadic {
                sig += ', '
            }
        }
        if node.is_c_variadic {
            sig += '...'
        }
    }
    sig += ')'
    return sig
}

fn (mut g Gen) c_call_name(node ast.CallExpr, cname string) string {
    if node.scope == unsafe { nil } {
        return cname
    }
    if node.scope.find_var(cname) == none && node.scope.find_global(cname) == none {
        return cname
    }
    g.global_tmp_count++
    alias_name := '__v_c_fn_${g.global_tmp_count}_${cname}'
    alias_sig := g.c_call_alias_signature(node, alias_name)
    cast_sig := g.c_call_alias_signature(node, '')
    g.definitions.writeln('${g.static_non_parallel}${alias_sig} = (${cast_sig})${cname};')
    if g.pref.parallel_cc {
        g.extern_out.writeln('extern ${alias_sig};')
    }
    return alias_name
}

fn (mut g Gen) closure_ctx(node ast.FnDecl) string {
    mut fn_name := node.name
    generic_names := if node.is_anon {
        g.anon_fn_generic_names(node.generic_names)
    } else {
        node.generic_names
    }
    if generic_names.len > 0 {
        fn_name = g.generic_fn_name(g.cur_concrete_types, fn_name)
    }
    return 'struct _V_${fn_name}_Ctx'
}

fn (mut g Gen) is_mut_closure_fixed_array(var ast.Param) bool {
    resolved_typ := g.recheck_concrete_type(var.typ)
    return var.is_mut && g.table.final_sym(resolved_typ).kind == .array_fixed
}

fn (mut g Gen) mut_closure_fixed_array_field_styp(var ast.Param) string {
    resolved_typ := g.recheck_concrete_type(var.typ)
    info := g.table.final_sym(resolved_typ).info as ast.ArrayFixed
    resolved_elem_type := g.recheck_concrete_type(info.elem_type)
    mut elem_styp := g.styp(resolved_elem_type.set_nr_muls(0))
    if resolved_elem_type.is_ptr() {
        elem_styp += '*'.repeat(resolved_elem_type.nr_muls())
    }
    return '${elem_styp}*'
}

fn (mut g Gen) closure_inherited_var_type(node ast.AnonFn, var ast.Param) ast.Type {
    resolved := g.resolve_current_fn_generic_param_type(var.name)
    if resolved != 0 {
        return g.unwrap_generic(g.recheck_concrete_type(resolved))
    }
    if node.decl.scope != unsafe { nil } && node.decl.scope.parent != unsafe { nil } {
        if scope_var := node.decl.scope.parent.find_var(var.name) {
            // If the scope variable has smartcasts and is a sumtype, use the
            // smartcast variant type instead of the original sumtype.
            if scope_var.smartcasts.len > 0 && g.table.type_kind(scope_var.typ) == .sum_type {
                return g.unwrap_generic(g.recheck_concrete_type(scope_var.smartcasts.last()))
            }
            // Only use resolved_expr_type for generic type resolution.
            // For non-generic types, scope_var.typ is already correct and
            // resolved_expr_type can produce wrong pointer levels (e.g. adding
            // an extra ref() for &receiver expressions).
            if scope_var.typ.has_flag(.generic)
                || g.type_has_unresolved_generic_parts(scope_var.typ) {
                if scope_var.expr !is ast.EmptyExpr {
                    resolved_expr_typ := g.resolved_expr_type(scope_var.expr, scope_var.typ)
                    if resolved_expr_typ != 0 {
                        return g.unwrap_generic(g.recheck_concrete_type(resolved_expr_typ))
                    }
                }
            }
            if scope_var.typ != 0 {
                return g.unwrap_generic(g.recheck_concrete_type(scope_var.typ))
            }
        }
    }
    return g.unwrap_generic(g.recheck_concrete_type(var.typ))
}

fn (g &Gen) variadic_voidptr_promoted_type(typ ast.Type) ast.Type {
    base_typ := g.table.unaliased_type(typ).clear_flags()
    if base_typ in ast.int_promoted_type_idxs || base_typ == ast.bool_type {
        return ast.int_type
    }
    if base_typ == ast.f32_type {
        return ast.f64_type
    }
    return ast.no_type
}

fn (mut g Gen) gen_anon_fn(mut node ast.AnonFn) {
    is_amp := g.is_amp
    g.is_amp = false
    defer {
        g.is_amp = is_amp
    }
    g.gen_anon_fn_decl(mut node)
    fn_name := g.gen_closure_fn_name(node)
    if !node.decl.scope.has_inherited_vars() {
        g.write(fn_name)
        return
    }
    ctx_struct := g.closure_ctx(node.decl)
    // it may be possible to optimize `memdup` out if the closure never leaves current scope
    // TODO: in case of an assignment, this should only call "closure_set_data" and "closure_set_function" (and free the former data)
    g.write('builtin__closure__closure_create_with_data(${fn_name}, (${ctx_struct}*) builtin__memdup(&(${ctx_struct}){')
    g.indent++
    for var in node.inherited_vars {
        mut has_inherited := false
        mut is_ptr := false
        var_name := c_name(var.name)
        // `ref_name` is how the captured variable is referenced in the enclosing
        // scope. For fn-typed local variables `fn_var_signature` emits `c_fn_name`,
        // so the RHS reference must match. The struct field name (LHS) stays as
        // `c_name(var.name)` to match `closure_field_cname` reads inside the body.
        mut ref_name := var_name
        if parent_obj := node.decl.scope.parent.find_var(var.name) {
            ref_name = g.var_cname(parent_obj)
        }
        if g.is_mut_closure_fixed_array(var) {
            if obj := node.decl.scope.find_var(var.name) {
                if obj.has_inherited {
                    has_inherited = true
                    g.writeln('.${var_name} = ${closure_ctx}->${var_name},')
                }
            }
            if !has_inherited {
                g.writeln('.${var_name} = ${ref_name},')
            }
            continue
        }
        if obj := node.decl.scope.find_var(var.name) {
            is_ptr = obj.typ.is_ptr()
            if obj.has_inherited {
                has_inherited = true
                resolved_var_typ := g.closure_inherited_var_type(node, var)
                var_sym := g.table.sym(resolved_var_typ)
                if var_sym.info is ast.ArrayFixed {
                    g.write('.${var_name} = {')
                    for i in 0 .. var_sym.info.size {
                        g.write('${closure_ctx}->${var_name}[${i}],')
                    }
                    g.writeln('},')
                } else if g.resolved_ident_is_by_value_auto_deref_capture(ast.Ident{
                    name:  var.name
                    scope: node.decl.scope
                })
                {
                    g.writeln('.${var_name} = *${closure_ctx}->${var_name},')
                } else {
                    g.writeln('.${var_name} = ${closure_ctx}->${var_name},')
                }
            }
        }
        if !has_inherited {
            resolved_var_typ := g.closure_inherited_var_type(node, var)
            var_sym := g.table.sym(resolved_var_typ)
            if var_sym.info is ast.ArrayFixed {
                g.write('.${var_name} = {')
                for i in 0 .. var_sym.info.size {
                    g.write('${ref_name}[${i}],')
                }
                g.writeln('},')
            } else if g.is_autofree && !var.is_mut && var_sym.info is ast.Array {
                g.writeln('.${var_name} = builtin__array_clone(&${ref_name}),')
            } else if g.is_autofree && !var.is_mut && var_sym.kind == .string {
                g.writeln('.${var_name} = builtin__string_clone(${ref_name}),')
            } else {
                mut is_auto_heap := false
                mut is_auto_deref_capture := false
                mut field_name := ''
                if obj := node.decl.scope.parent.find(var.name) {
                    if obj is ast.Var {
                        is_auto_heap = !obj.is_stack_obj && obj.is_auto_heap
                        is_auto_deref_capture = obj.is_auto_deref
                            && (!var.is_mut || g.table.sym(obj.typ).kind == .alias)
                            && (is_ptr || obj.typ.is_ptr())
                        if obj.smartcasts.len > 0 {
                            if g.table.type_kind(obj.typ) == .sum_type {
                                cast_sym := g.table.sym(obj.smartcasts.last())
                                field_name += '._${cast_sym.cname}'
                            }
                        }
                    }
                }
                if (is_auto_heap && !is_ptr) || is_auto_deref_capture || field_name != '' {
                    g.writeln('.${var_name} = *${ref_name}${field_name},')
                } else {
                    g.writeln('.${var_name} = ${ref_name},')
                }
            }
        }
    }
    g.indent--
    g.write('}, sizeof(${ctx_struct})), true)')

    g.empty_line = false
}

fn (mut g Gen) gen_anon_fn_decl(mut node ast.AnonFn) {
    mut fn_name := g.gen_closure_fn_name(node)
    if node.has_gen[fn_name] {
        return
    }
    mut builder := strings.new_builder(256)
    // Generate a closure struct
    if node.inherited_vars.len > 0 {
        ctx_struct := g.closure_ctx(node.decl)
        if ctx_struct !in g.closure_structs {
            g.closure_structs << ctx_struct
            g.definitions.writeln('${ctx_struct} {')
            for var in node.inherited_vars {
                mut resolved_var_typ := g.closure_inherited_var_type(node, var)
                // When the variable is auto-heap promoted, the closure struct
                // stores the dereferenced value (the init code does `*var`),
                // so strip one pointer level from the field type.
                // Similarly, when a `mut` parameter (is_auto_deref) is captured
                // without `mut`, the closure stores the dereferenced value.
                // For alias types (`type AppRef = &App`), the deref is needed for
                // `mut` captures too, since the alias adds an indirection level.
                if node.decl.scope != unsafe { nil } && node.decl.scope.parent != unsafe { nil } {
                    if scope_var := node.decl.scope.parent.find_var(var.name) {
                        if scope_var.is_auto_heap && !scope_var.is_stack_obj
                            && resolved_var_typ.is_ptr() {
                            resolved_var_typ = resolved_var_typ.deref()
                        } else if scope_var.is_auto_deref
                            && (!var.is_mut || g.table.sym(scope_var.typ).kind == .alias)
                            && resolved_var_typ.is_ptr() {
                            resolved_var_typ = resolved_var_typ.deref()
                        }
                    }
                }
                var_sym := g.table.sym(resolved_var_typ)
                if g.is_mut_closure_fixed_array(var) {
                    g.definitions.writeln('\t${g.mut_closure_fixed_array_field_styp(var)} ${c_name(var.name)};')
                } else if var_sym.info is ast.FnType {
                    resolved_ret_type := g.recheck_concrete_type(var_sym.info.func.return_type)
                    resolved_param_types :=
                        var_sym.info.func.params.map(g.recheck_concrete_type(it.typ))
                    mut sig := g.fn_var_signature(resolved_var_typ, resolved_ret_type,
                        resolved_param_types, c_name(var.name))
                    g.definitions.writeln('\t' + sig + ';')
                } else {
                    styp := g.styp(resolved_var_typ)
                    g.definitions.writeln('\t${styp} ${c_name(var.name)};')
                }
            }
            g.definitions.writeln('};\n')
        }
    }
    pos := g.out.len
    was_anon_fn := g.anon_fn
    prev_stmt_path_pos := g.stmt_path_pos.clone()
    prev_skip_stmt_pos := g.skip_stmt_pos
    decl := ast.FnDecl{
        ...node.decl
        generic_names: g.anon_fn_generic_names(node.decl.generic_names)
    }
    g.stmt_path_pos = []
    g.skip_stmt_pos = false
    g.anon_fn = node
    old_inside_return := g.inside_return
    old_inside_return_expr := g.inside_return_expr
    old_inside_lambda := g.inside_lambda
    old_inside_lambda_autofree_tmp := g.inside_lambda_autofree_tmp
    old_track_lambda_autofree_tmp_arg_vars := g.track_lambda_autofree_tmp_arg_vars
    g.inside_return = false
    g.inside_return_expr = false
    g.inside_lambda = false
    g.inside_lambda_autofree_tmp = false
    g.track_lambda_autofree_tmp_arg_vars = false
    g.fn_decl(decl)
    g.track_lambda_autofree_tmp_arg_vars = old_track_lambda_autofree_tmp_arg_vars
    g.inside_lambda_autofree_tmp = old_inside_lambda_autofree_tmp
    g.inside_lambda = old_inside_lambda
    g.inside_return_expr = old_inside_return_expr
    g.inside_return = old_inside_return
    g.anon_fn = was_anon_fn
    g.skip_stmt_pos = prev_skip_stmt_pos
    g.stmt_path_pos = prev_stmt_path_pos
    builder.write_string(g.out.cut_to(pos))
    out := builder.str()
    if out.len == 0 {
        return
    }
    node.has_gen[fn_name] = true
    g.anon_fn_definitions << out
    if g.pref.parallel_cc {
        g.extern_out.writeln('extern ${out.all_before(' {')};')
    }
}

fn (mut g Gen) fn_decl_params(params []ast.Param, scope &ast.Scope, is_variadic bool, is_c_variadic bool) ([]string, []string, []bool) {
    mut fparams := []string{}
    mut fparamtypes := []string{}
    mut heap_promoted := []bool{}
    param_count := if is_c_variadic && is_variadic && params.len > 0
        && params.last().typ.has_flag(.variadic) {
        params.len - 1
    } else {
        params.len
    }
    if param_count == 0 {
        // in C, `()` is untyped, unlike `(void)`
        if !g.inside_c_extern && !is_c_variadic {
            g.write('void')
        }
    }
    for i, param in params {
        if i >= param_count {
            break
        }
        mut typ := if !param.typ.has_flag(.variadic) && g.cur_concrete_types.len > 0
            && param.orig_typ != 0 && (param.orig_typ.has_flag(.generic)
            || g.type_has_unresolved_generic_parts(param.orig_typ)) {
            g.resolve_current_fn_generic_type(param.orig_typ)
        } else {
            g.unwrap_generic(param.typ)
        }
        if g.pref.translated && g.file.is_translated && param.typ.has_flag(.variadic) {
            typ = g.table.sym(typ).array_info().elem_type.set_flag(.variadic)
        }
        // A `mut x T` parameter is passed by reference, so its C type must be a pointer to
        // the concrete type. The normal solver keeps `.generic` on `param.typ` here, but the
        // new generic solver pre-resolves `param.typ` to the concrete type (dropping the flag),
        // so it would otherwise miss the indirection. `param.orig_typ` still carries the
        // generic `T`, which resolves correctly via `cur_concrete_types`.
        if param.is_mut && param.orig_typ != 0 && param.orig_typ.has_flag(.generic)
            && (param.typ.has_flag(.generic) || g.pref.new_generic_solver) {
            mut surface_typ := g.unwrap_generic(param.orig_typ)
            // Only use ref() when the pointer comes from the generic type argument
            // (T=&int), not from the param signature (&T / ?&T).
            orig_was_ptr := param.orig_typ.nr_muls() > 0
            typ = if surface_typ.is_ptr() && !orig_was_ptr {
                surface_typ.ref()
            } else {
                surface_typ.set_nr_muls(1)
            }
            if typ.has_flag(.option) {
                typ = typ.set_flag(.option_mut_param_t)
            }
        }
        if param.is_mut && param.typ.has_flag(.generic) && typ.has_flag(.option) {
            typ = typ.set_flag(.option_mut_param_t).set_nr_muls(param.typ.nr_muls() - 1)
        }
        if param.is_mut && param.orig_typ != 0 && param.orig_typ.has_flag(.option)
            && typ.has_flag(.option_mut_param_t) && typ.nr_muls() == 1
            && !g.mut_option_param_assigned_directly(param.name) {
            typ = typ.ref()
        }
        param_type_sym := g.table.sym(typ)
        mut caname := if param.name in ['', '_'] {
            '_d${i + 1}'
        } else if param_type_sym.kind == .function && !typ.has_flag(.option) {
            c_fn_name(param.name)
        } else {
            c_name(param.name)
        }
        mut param_type_name := g.styp(typ)
        if param.typ.has_flag(.generic) {
            param_type_name = param_type_name.replace_each(c_fn_name_escape_seq)
        }
        if param_type_sym.kind == .function && !typ.has_flag(.option) {
            info := param_type_sym.info as ast.FnType
            func := info.func
            if !g.inside_c_extern {
                g.write('${g.ret_styp(func.return_type)} (*${caname})(')
            }
            g.definitions.write_string('${g.ret_styp(func.return_type)} (*${caname})(')
            g.fn_decl_params(func.params, unsafe { nil }, func.is_variadic, func.is_c_variadic)
            if !g.inside_c_extern {
                g.write(')')
            }
            g.definitions.write_string(')')
            fparams << caname
            fparamtypes << param_type_name
            heap_promoted << false
        } else {
            mut heap_prom := false
            if scope != unsafe { nil } {
                if param.name != '_' {
                    if v := scope.find_var(param.name) {
                        if !v.is_stack_obj && v.is_auto_heap {
                            heap_prom = true
                        }
                    }
                }
            }
            var_name_prefix := if heap_prom { '_v_toheap_' } else { '' }
            const_prefix := if param.typ.is_any_kind_of_pointer() && !param.is_mut
                && param.name.starts_with('const_') {
                'const '
            } else {
                ''
            }
            const_param_type_name := if const_prefix != '' {
                g.const_pointer_param_type_name(typ, param_type_name)
            } else {
                param_type_name
            }
            s := '${const_prefix}${const_param_type_name} ${var_name_prefix}${caname}'
            if !g.inside_c_extern {
                g.write(s)
            }
            g.definitions.write_string(s)
            fparams << caname
            fparamtypes << param_type_name
            heap_promoted << heap_prom
        }
        if i < param_count - 1 {
            if !g.inside_c_extern {
                g.write(', ')
            }
            g.definitions.write_string(', ')
        }
    }
    if ((g.pref.translated && is_variadic) || is_c_variadic) && (!is_c_variadic || param_count > 0) {
        if param_count > 0 {
            if !g.inside_c_extern {
                g.write(', ')
            }
            g.definitions.write_string(', ')
        }
        if !g.inside_c_extern {
            g.write('... ')
        }
        g.definitions.write_string('... ')
    }
    return fparams, fparamtypes, heap_promoted
}

fn (g &Gen) mut_option_param_assigned_directly(name string) bool {
    if g.cur_fn == unsafe { nil } {
        return false
    }
    for stmt in g.cur_fn.stmts {
        if stmt is ast.AssignStmt {
            for left in stmt.left {
                if left is ast.Ident && left.name == name {
                    return true
                }
            }
        }
    }
    return false
}

fn (mut g Gen) const_pointer_param_type_name(typ ast.Type, param_type_name string) string {
    unwrapped_typ := g.unwrap_generic(typ)
    return match unwrapped_typ {
        ast.voidptr_type { 'void*' }
        ast.byteptr_type { 'u8*' }
        ast.charptr_type { 'char*' }
        else { param_type_name }
    }
}

fn (mut g Gen) get_anon_fn_type_name(mut node ast.AnonFn, var_name string) string {
    mut builder := strings.new_builder(64)
    return_styp := g.styp(node.decl.return_type)
    builder.write_string('${return_styp} (*${var_name}) (')
    if node.decl.params.len == 0 {
        builder.write_string('void)')
    } else {
        for i, param in node.decl.params {
            param_styp := g.styp(param.typ)
            builder.write_string('${param_styp} ${param.name}')
            if i != node.decl.params.len - 1 {
                builder.write_string(', ')
            }
        }
        builder.write_string(')')
    }
    return builder.str()
}

fn (mut g Gen) call_expr(node ast.CallExpr) {
    if node.should_be_skipped {
        return
    }
    if node.is_c_type_cast {
        g.cast_expr(ast.CastExpr{
            typ:       node.return_type
            typname:   g.table.sym(g.unwrap_generic(node.return_type)).name
            expr:      node.args[0].expr
            expr_type: node.args[0].typ
            pos:       node.pos
        })
        return
    }
    is_shared := g.is_shared
    g.is_shared = false
    defer {
        g.is_shared = is_shared
    }
    // NOTE: everything could be done this way
    // see my comment in parser near anon_fn
    mut tmp_anon_fn_var := ''
    mut tmp_fn_result_var := ''
    mut needs_tmp_fn_result_cleanup := false
    if node.left is ast.AnonFn {
        if node.left.inherited_vars.len > 0 {
            tmp_anon_fn_var = g.new_tmp_var()
            fn_type := g.fn_var_signature(ast.void_type, node.left.decl.return_type,
                node.left.decl.params.map(it.typ), tmp_anon_fn_var)
            line := g.go_before_last_stmt().trim_space()
            g.empty_line = true
            g.write('${fn_type} = ')
            g.expr(ast.Expr(node.left))
            g.writeln(';')
            g.set_current_pos_as_last_stmt_pos()
            g.write(line)
            if node.or_block.kind == .absent {
                if g.out.last_n(1) != '\n' {
                    g.writeln('')
                }
                g.write(tmp_anon_fn_var)
            }
        } else if node.or_block.kind == .absent {
            g.expr(ast.Expr(node.left))
        }
    } else if !g.inside_curry_call && node.left is ast.IndexExpr && node.name == '' {
        if node.or_block.kind == .absent {
            old_is_fn_index_call := g.is_fn_index_call
            g.is_fn_index_call = true
            g.expr(ast.Expr(node.left))
            g.is_fn_index_call = old_is_fn_index_call
        } else {
            // map1['key']() handling
            line := g.go_before_last_stmt()
            g.empty_line = true

            // temp var for map1['key'] where value is a fn to be called
            left_typ := g.table.value_type(node.left.left_type)
            tmp_res := g.new_tmp_var()
            fn_sym := g.table.sym(left_typ).info as ast.FnType
            fn_type := g.fn_var_signature(ast.void_type, fn_sym.func.return_type,
                fn_sym.func.params.map(it.typ), tmp_res)

            old_is_fn_index_call := g.is_fn_index_call
            g.is_fn_index_call = true
            g.write('${fn_type} = ')
            g.expr(ast.Expr(node.left))
            g.is_fn_index_call = old_is_fn_index_call
            g.writeln(';')

            tmp_res2 := g.new_tmp_var()
            // uses the `tmp_res` as fn name (where it is a ptr to fn var)
            g.write('${g.styp(node.return_type)} ${tmp_res2} = ${tmp_res}')
            g.last_tmp_call_var << tmp_res2
            old_inside_curry_call := g.inside_curry_call
            g.inside_curry_call = true
            // map1['key']()() handling
            g.expr(node)
            g.inside_curry_call = old_inside_curry_call
            g.write2(line, '*(${g.base_type(node.return_type)}*)${tmp_res2}.data')
            return
        }
    } else if !g.inside_curry_call && node.left is ast.CallExpr && node.name == '' {
        if node.or_block.kind == .absent {
            left_return_typ := g.recheck_concrete_type(g.unwrap_generic(node.left.return_type))
            if g.table.used_features.anon_fn && g.table.final_sym(left_return_typ).kind == .function {
                tmp_fn_result_var = g.new_tmp_var()
                fn_sym := g.table.final_sym(left_return_typ).info as ast.FnType
                fn_type := g.fn_var_signature(ast.void_type, fn_sym.func.return_type,
                    fn_sym.func.params.map(it.typ), tmp_fn_result_var)
                line := g.go_before_last_stmt().trim_space()
                g.empty_line = true
                g.write('${fn_type} = ')
                g.expr(ast.Expr(node.left))
                g.writeln(';')
                g.set_current_pos_as_last_stmt_pos()
                g.write(line)
                if g.out.last_n(1) != '\n' {
                    g.writeln('')
                }
                g.write(tmp_fn_result_var)
                needs_tmp_fn_result_cleanup = true
            } else {
                g.expr(ast.Expr(node.left))
            }
        } else {
            ret_typ := node.return_type

            line := g.go_before_last_stmt()
            g.empty_line = true

            tmp_res := g.new_tmp_var()
            g.write('${g.styp(ret_typ)} ${tmp_res} = ')

            g.last_tmp_call_var << tmp_res
            g.expr(ast.Expr(node.left))

            old_inside_curry_call := g.inside_curry_call
            g.inside_curry_call = true
            g.expr(node)
            g.inside_curry_call = old_inside_curry_call
            g.write2(line, '*(${g.base_type(ret_typ)}*)${tmp_res}.data')
            return
        }
    } else if !g.inside_curry_call && node.left is ast.SelectorExpr && node.name == '' {
        if node.or_block.kind == .absent {
            g.expr(ast.Expr(node.left))
        } else {
            ret_typ := node.return_type

            line := g.go_before_last_stmt()
            g.empty_line = true

            tmp_res := g.new_tmp_var()
            g.write('${g.styp(ret_typ)} ${tmp_res} = ')

            g.last_tmp_call_var << tmp_res
            g.expr(ast.Expr(node.left))

            old_inside_curry_call := g.inside_curry_call
            g.inside_curry_call = true
            g.expr(node)
            g.inside_curry_call = old_inside_curry_call
            g.write2(line, '*(${g.base_type(ret_typ)}*)${tmp_res}.data')
            return
        }
    }
    closure_frame_arg_tmps := g.prepare_closure_lifetime_arg_tmps(node)
    defer {
        for pos in closure_frame_arg_tmps.keys() {
            g.closure_frame_arg_tmps.delete(pos)
        }
    }
    old_inside_call := g.inside_call
    g.inside_call = true
    // Reset inside_selector_lhs so that receiver expressions inside method
    // calls generate proper auto-heap dereferences. Without this, when a
    // method call is nested inside a selector (e.g. exa.payload()!.len),
    // the selector's inside_selector_lhs flag would leak into the receiver
    // generation and suppress the (*(exa)) deref.
    old_inside_selector_lhs := g.inside_selector_lhs
    g.inside_selector_lhs = false
    defer {
        g.inside_call = old_inside_call
        g.inside_selector_lhs = old_inside_selector_lhs
    }
    gen_keep_alive := node.is_keep_alive && node.return_type != ast.void_type
        && g.pref.gc_mode in [.boehm_full, .boehm_incr, .boehm_full_opt, .boehm_incr_opt]
    gen_or := node.or_block.kind != .absent // && !g.is_autofree
    is_gen_or_and_assign_rhs := gen_or && !g.discard_or_result
    mut cur_line := if !g.inside_curry_call && (is_gen_or_and_assign_rhs || gen_keep_alive) { // && !g.is_autofree {
        // `x := foo() or { ...}`
        // cut everything that has been generated to prepend option variable creation
        line := g.go_before_last_stmt()
        g.out.write_string(util.tabs(g.indent))
        line
    } else {
        ''
    }
    // g.write('/*EE line="${cur_line}"*/')
    tmp_opt := if gen_or || gen_keep_alive {
        if g.inside_curry_call && g.last_tmp_call_var.len > 0 {
            g.last_tmp_call_var.pop()
        } else if !g.inside_or_block {
            new_tmp := g.new_tmp_var()
            g.last_tmp_call_var << new_tmp
            new_tmp
        } else {
            g.new_tmp_var()
        }
    } else {
        ''
    }
    mut tmp_fn_result_call_value := ''
    mut tmp_fn_result_call_line := ''
    if needs_tmp_fn_result_cleanup && !gen_or && !gen_keep_alive && !g.inside_curry_call
        && node.return_type != 0 && node.return_type != ast.void_type {
        tmp_fn_result_call_line = g.go_before_last_stmt()
        if tmp_fn_result_call_line.ends_with(tmp_fn_result_var) {
            tmp_fn_result_call_line = tmp_fn_result_call_line[..tmp_fn_result_call_line.len - tmp_fn_result_var.len]
        }
        g.empty_line = true
        tmp_fn_result_call_value = g.new_tmp_var()
        g.write('${g.styp(node.return_type)} ${tmp_fn_result_call_value} = ${tmp_fn_result_var}')
    }
    mut effective_return_type := node.return_type
    if (gen_or || gen_keep_alive) && node.return_type != 0 {
        mut ret_typ := effective_return_type
        resolved_ret_typ := g.resolve_return_type(node)
        if resolved_ret_typ != ast.void_type && !resolved_ret_typ.has_flag(.generic)
            && !g.type_has_unresolved_generic_parts(resolved_ret_typ) {
            if node.return_type.has_flag(.result) && !resolved_ret_typ.has_flag(.result) {
                ret_typ = resolved_ret_typ.set_flag(.result)
            } else if node.return_type.has_flag(.option) && !resolved_ret_typ.has_flag(.option) {
                ret_typ = resolved_ret_typ.set_flag(.option)
            } else {
                ret_typ = resolved_ret_typ
            }
        } else if g.table.sym(ret_typ).kind == .alias {
            unaliased_type := g.table.unaliased_type(ret_typ)
            if unaliased_type.has_option_or_result() {
                ret_typ = unaliased_type
            }
        } else if node.return_type_generic != 0 {
            unwrapped_ret_typ := g.unwrap_generic(node.return_type_generic)
            if !unwrapped_ret_typ.has_flag(.generic) {
                ret_sym := g.table.sym(unwrapped_ret_typ)
                if ret_sym.info is ast.Array && g.table.sym(node.return_type_generic).kind == .array {
                    // Make []T returns T type when array was supplied to T
                    if g.table.type_to_str(node.return_type_generic).count('[]') < g.table.type_to_str(unwrapped_ret_typ).count('[]') {
                        ret_typ = g.unwrap_generic(ret_sym.info.elem_type).derive(unwrapped_ret_typ)
                    }
                }
            } else if g.cur_fn != unsafe { nil } && g.cur_fn.is_method
                && g.cur_fn.receiver.typ.has_flag(.generic) && g.cur_concrete_types.len > 0 {
                // unwrap_generic failed because cur_fn.generic_names is empty
                // (generics come from the receiver, not the method itself).
                // Use the receiver's generic type names to resolve.
                receiver_generic_names := g.table.generic_type_names(g.cur_fn.receiver.typ)
                if receiver_generic_names.len == g.cur_concrete_types.len {
                    if gen_type := g.table.convert_generic_type(node.return_type_generic,
                        receiver_generic_names, g.cur_concrete_types)
                    {
                        if !gen_type.has_flag(.generic) {
                            ret_typ = gen_type
                        }
                    }
                }
            }
        }
        effective_return_type = ret_typ
        mut styp := g.styp(ret_typ)
        if gen_or && !is_gen_or_and_assign_rhs {
            cur_line = g.go_before_last_stmt()
        }
        if gen_or && g.infix_left_var_name.len > 0 {
            g.writeln('${styp} ${tmp_opt};')
            g.writeln('if (${g.infix_left_var_name}) {')
            g.indent++
            g.write('${tmp_opt} = ')
        } else if !g.inside_curry_call {
            if g.assign_ct_type[node.pos.pos] != 0 && node.or_block.kind != .absent {
                styp = g.styp(g.assign_ct_type[node.pos.pos].derive(ret_typ))
            }
            g.write('${styp} ${tmp_opt} = ')
            if node.left is ast.AnonFn {
                if node.left.inherited_vars.len > 0 {
                    g.write(tmp_anon_fn_var)
                } else {
                    g.expr(ast.Expr(node.left))
                }
            }
        }
    }
    if node.is_method && !node.is_field {
        if g.pref.experimental && node.args.len > 0 && node.kind == .writeln
            && node.args[0].expr is ast.StringInterLiteral
            && g.table.sym(node.receiver_type).name == 'strings.Builder' {
            g.string_inter_literal_sb_optimized(node)
        } else {
            g.method_call(node)
        }
    } else {
        g.fn_call(node)
    }
    if closure_frame_arg_tmps.len > 0 {
        g.writeln(';')
        for _, tmp in closure_frame_arg_tmps {
            g.writeln('builtin__closure__closure_try_destroy((voidptr)${tmp});')
        }
        g.set_current_pos_as_last_stmt_pos()
    }
    if needs_tmp_fn_result_cleanup && !gen_or && !gen_keep_alive && !g.inside_curry_call {
        if node.return_type == ast.void_type {
            g.writeln(';')
            g.write('builtin__closure__closure_try_destroy((voidptr)${tmp_fn_result_var})')
            g.set_current_pos_as_last_stmt_pos()
        } else if tmp_fn_result_call_value != '' {
            g.writeln(';')
            g.writeln('builtin__closure__closure_try_destroy((voidptr)${tmp_fn_result_var});')
            g.write2(tmp_fn_result_call_line, tmp_fn_result_call_value)
        }
    }
    if gen_or && node.return_type != 0 {
        g.or_block(tmp_opt, node.or_block, effective_return_type)
        mut unwrapped_typ := effective_return_type.clear_option_and_result()
        if g.table.sym(unwrapped_typ).kind == .alias {
            unaliased_type := g.table.unaliased_type(unwrapped_typ)
            if unaliased_type.has_option_or_result() {
                unwrapped_typ = unaliased_type.clear_option_and_result()
            }
        }
        mut unwrapped_styp := g.styp(unwrapped_typ)
        if g.infix_left_var_name.len > 0 {
            g.indent--
            g.writeln('}')
            g.set_current_pos_as_last_stmt_pos()
        }
        if unwrapped_typ == ast.void_type {
            g.write('\n ${cur_line}')
        } else if !g.inside_curry_call {
            if !g.inside_const_opt_or_res {
                if g.assign_ct_type[node.pos.pos] != 0 && node.or_block.kind != .absent {
                    unwrapped_styp =
                        g.styp(g.assign_ct_type[node.pos.pos].derive(effective_return_type).clear_option_and_result())
                }
                if g.table.sym(effective_return_type).kind == .array_fixed
                    && unwrapped_styp.starts_with('_v_') {
                    unwrapped_styp = unwrapped_styp[3..]
                }
                // Synthesized/transformed call nodes may lose `is_return_used`
                // even though the enclosing C generation path is still
                // emitting a value expression (struct fields, call args, etc).
                // In those cases `is_gen_or_and_assign_rhs` still tells us that
                // the unwrapped result is needed in the current expression.
                if node.is_return_used || is_gen_or_and_assign_rhs {
                    is_fn := g.table.final_sym(unwrapped_typ).kind == .function
                    // return value is used, so we need to write the unwrapped temporary var
                    if is_fn && unwrapped_typ.nr_muls() > 0 {
                        g.write('\n ${cur_line}((${unwrapped_styp}*)${tmp_opt}.data)')
                    } else {
                        g.write('\n ${cur_line}(*(${unwrapped_styp}*)${tmp_opt}.data)')
                    }
                } else {
                    g.write('\n ${cur_line}')
                }
            } else {
                if !g.inside_or_block && g.last_tmp_call_var.len > 0 && !cur_line.contains(' = ') {
                    g.write('\n\t*(${unwrapped_styp}*)${g.last_tmp_call_var.pop()}.data = ${cur_line}(*(${unwrapped_styp}*)${tmp_opt}.data)')
                } else {
                    g.write('\n ${cur_line}(*(${unwrapped_styp}*)${tmp_opt}.data)')
                }
            }
        }
    } else if gen_keep_alive && node.return_type != 0 {
        if node.return_type == ast.void_type {
            g.write('\n ${cur_line}')
        } else {
            g.write('\n ${cur_line} ${tmp_opt}')
        }
    }
    if node.is_noreturn {
        if g.inside_ternary == 0 {
            g.writeln(';')
            g.write('VUNREACHABLE()')
        } else {
            $if msvc {
                // MSVC has no support for the statement expressions used below
            } $else {
                g.write(', ({VUNREACHABLE();})')
            }
        }
    }
}

fn (mut g Gen) is_closure_lifetime_callback_call(node ast.CallExpr) bool {
    method_name := node.name.all_after_last('.')
    if !node.is_method || method_name !in ['frame', 'suspend', 'untracked'] || node.args.len != 1 {
        return false
    }
    mut receiver_type := g.unwrap_generic(node.receiver_type)
    if receiver_type == 0 {
        receiver_type = g.unwrap_generic(node.left_type)
    }
    if receiver_type == 0 {
        return false
    }
    if receiver_type.is_ptr() {
        receiver_type = receiver_type.deref()
    }
    return g.table.sym(receiver_type).name == 'builtin.closure.Lifetime'
}

fn (mut g Gen) closure_lifetime_arg_needs_tmp(expr ast.Expr) bool {
    unwrapped_expr := expr.remove_par()
    return match unwrapped_expr {
        ast.AnonFn {
            unwrapped_expr.inherited_vars.len > 0
        }
        ast.SelectorExpr {
            unwrapped_expr.has_hidden_receiver
        }
        else {
            false
        }
    }
}

fn (mut g Gen) call_needs_closure_lifetime_arg_tmp(node ast.CallExpr) bool {
    return g.is_closure_lifetime_callback_call(node)
        && g.closure_lifetime_arg_needs_tmp(node.args[0].expr)
}

fn (mut g Gen) closure_lifetime_fn_type_tmp_signature(fn_types []ast.Type, tmp string) ?string {
    for raw_fn_typ in fn_types {
        fn_typ := g.unwrap_generic(g.recheck_concrete_type(raw_fn_typ))
        if fn_typ == 0 {
            continue
        }
        fn_sym := g.table.final_sym(fn_typ)
        if fn_sym.info is ast.FnType {
            func := fn_sym.info.func
            return g.fn_var_signature(ast.void_type, func.return_type, func.params.map(it.typ), tmp)
        }
    }
    return none
}

fn (mut g Gen) closure_lifetime_arg_tmp_signature(node ast.CallExpr, arg ast.CallArg, tmp string) ?string {
    unwrapped_expr := arg.expr.remove_par()
    match unwrapped_expr {
        ast.AnonFn {
            return g.fn_var_signature(ast.void_type, unwrapped_expr.decl.return_type,
                unwrapped_expr.decl.params.map(it.typ), tmp)
        }
        ast.SelectorExpr {
            mut fn_types := []ast.Type{}
            if arg.typ != 0 {
                fn_types << arg.typ
            }
            if unwrapped_expr.typ != 0 {
                fn_types << unwrapped_expr.typ
            }
            if node.expected_arg_types.len > 0 && node.expected_arg_types[0] != 0 {
                fn_types << node.expected_arg_types[0]
            }
            return g.closure_lifetime_fn_type_tmp_signature(fn_types, tmp)
        }
        else {}
    }

    return none
}

fn (mut g Gen) prepare_closure_lifetime_arg_tmps(node ast.CallExpr) map[int]string {
    mut tmps := map[int]string{}
    if !g.call_needs_closure_lifetime_arg_tmp(node) {
        return tmps
    }
    arg := node.args[0]
    tmp := g.new_tmp_var()
    fn_type := g.closure_lifetime_arg_tmp_signature(node, arg, tmp) or { return tmps }
    line := g.go_before_last_stmt().trim_space()
    g.empty_line = true
    g.write('${fn_type} = ')
    g.expr(ast.Expr(arg.expr))
    g.writeln(';')
    g.set_current_pos_as_last_stmt_pos()
    g.write(line)
    tmps[arg.pos.pos] = tmp
    g.closure_frame_arg_tmps[arg.pos.pos] = tmp
    return tmps
}

fn (mut g Gen) conversion_function_call(prefix string, postfix string, node ast.CallExpr) {
    g.write('${prefix}( (')
    g.expr(node.left)
    dot := if node.left_type.is_ptr() { '->' } else { '.' }
    g.write(')${dot}_typ )${postfix}')
}

@[inline]
fn (mut g Gen) write_raw_receiver_expr(node ast.Expr) {
    old_inside_selector_lhs := g.inside_selector_lhs
    g.inside_selector_lhs = true
    defer {
        g.inside_selector_lhs = old_inside_selector_lhs
    }
    g.expr(node)
}

@[inline]
fn (mut g Gen) gen_arg_from_type(node_type ast.Type, node ast.Expr) {
    is_auto_heap_ident := node is ast.Ident && g.resolved_ident_is_auto_heap(node)
    if node_type.has_flag(.shared_f) {
        if node_type.is_ptr() || is_auto_heap_ident {
            g.write('&')
        }
        if is_auto_heap_ident {
            g.write_raw_receiver_expr(node)
        } else {
            g.expr(node)
        }
        g.write('->val')
    } else {
        if node_type.is_ptr() || is_auto_heap_ident {
            if is_auto_heap_ident {
                g.write_raw_receiver_expr(node)
            } else {
                g.expr(node)
            }
        } else if !node.is_lvalue()
            || (node is ast.Ident && g.table.is_interface_smartcast(node.obj)) {
            g.write('ADDR(${g.styp(node_type)}, ')
            g.expr(node)
            g.write(')')
        } else {
            g.write('&')
            g.expr(node)
        }
    }
}

fn (mut g Gen) gen_map_method_call(node ast.CallExpr, left_type ast.Type, left_sym ast.TypeSymbol) bool {
    match node.kind {
        .reserve {
            g.write('builtin__map_reserve(')
            g.gen_arg_from_type(left_type, node.left)
            g.write(', ')
            g.expr(node.args[0].expr)
            g.write(')')
        }
        .delete {
            elem_type_str := if left_sym.info is ast.Map {
                g.styp(left_sym.info.key_type)
            } else {
                // In generic contexts, the left type may resolve to the base
                // `map` struct rather than a concrete `map[K]V`. Resolve the
                // key type from the argument expression instead.
                arg_type := g.unwrap_generic(g.resolved_expr_type(node.args[0].expr,
                    node.args[0].typ))
                g.styp(arg_type)
            }
            g.write('builtin__map_delete(')
            g.gen_arg_from_type(left_type, node.left)
            g.write(', &(${elem_type_str}[]){')
            g.expr(node.args[0].expr)
            g.write('})')
        }
        .free, .clear, .keys, .values {
            g.write('builtin__map_${node.name}(')
            g.gen_arg_from_type(left_type, node.left)
            g.write(')')
        }
        else {
            return false
        }
    }

    return true
}

fn (mut g Gen) gen_array_method_call(node ast.CallExpr, left_type ast.Type, left_sym ast.TypeSymbol) bool {
    if node.name == 'get' {
        g.gen_array_get(node)
        return true
    }
    match node.kind {
        .filter {
            g.gen_array_filter(node)
        }
        .sort {
            g.gen_array_sort(node)
        }
        .sorted {
            g.gen_array_sorted(node)
        }
        .sort_with_compare {
            if !g.gen_array_sort_with_compare(node) {
                return false
            }
        }
        .sorted_with_compare {
            if !g.gen_array_sorted_with_compare(node) {
                return false
            }
        }
        .insert {
            g.gen_array_insert(node)
        }
        .map {
            g.gen_array_map(node)
        }
        .prepend {
            g.gen_array_prepend(node)
        }
        .contains {
            g.gen_array_contains(left_type, node.left, node.args[0].typ, node.args[0].expr)
        }
        .index {
            g.gen_array_index(node, false)
        }
        .last_index {
            g.gen_array_index(node, true)
        }
        .wait {
            g.gen_array_wait(node)
        }
        .any {
            g.gen_array_any(node)
        }
        .count {
            g.gen_array_count(node)
        }
        .all {
            g.gen_array_all(node)
        }
        .delete, .drop, .delete_last, .delete_many {
            g.write('builtin__array_${node.name}(')
            g.gen_arg_from_type(left_type, node.left)
            if node.kind != .delete_last {
                g.write(', ')
                g.expr(node.args[0].expr)
                if node.kind == .delete_many {
                    g.write(', ')
                    g.expr(node.args[1].expr)
                }
            }
            g.write(')')
        }
        .grow_cap, .grow_len {
            g.write('builtin__array_${node.name}(')
            g.gen_arg_from_type(left_type, node.left)
            g.write(', ')
            g.expr(node.args[0].expr)
            g.write(')')
        }
        .first, .last, .pop_left, .pop {
            mut noscan := ''
            array_info := left_sym.info as ast.Array
            if node.kind in [.pop_left, .pop] {
                noscan = g.check_noscan(array_info.elem_type)
            }
            return_type := g.resolved_array_builtin_method_return_type(node, left_type,
                node.return_type)
            return_type_str := g.styp(return_type)
            g.write('(*(${return_type_str}*)builtin__array_${node.name}${noscan}(')
            if node.kind in [.pop_left, .pop] {
                g.gen_arg_from_type(left_type, node.left)
            } else {
                if node.left_type.is_ptr() || node.left.is_auto_deref_var() {
                    g.write('(*')
                    g.expr(node.left)
                    g.write(')')
                } else {
                    g.expr(node.left)
                }
                if left_type.has_flag(.shared_f) {
                    g.write('.val')
                }
            }
            g.write('))')
        }
        .clone, .repeat {
            array_info := left_sym.info as ast.Array
            elem_sym :=
                g.table.final_sym(g.table.unaliased_type(g.unwrap_generic(array_info.elem_type)))
            if node.kind == .repeat && elem_sym.kind == .interface {
                fn_name := g.register_array_interface_repeat_fn(g.resolve_return_type(node))
                g.write('${fn_name}(')
                if node.left_type.is_ptr() {
                    g.write('*'.repeat(node.left_type.nr_muls()))
                }
                g.expr(ast.Expr(node.left))
                g.write(', ')
                g.expr(node.args[0].expr)
                g.write(')')
                return true
            }
            array_depth := g.get_array_depth(array_info.elem_type)
            to_depth := if array_depth >= 0 { '_to_depth' } else { '' }
            mut is_range_slice := false
            if node.left is ast.IndexExpr && node.left.index is ast.RangeExpr && node.kind == .clone {
                is_range_slice = true
            }
            to_static := if is_range_slice { '_static' } else { '' }
            g.write('builtin__array_${node.name}${to_static}${to_depth}(')
            if node.kind == .clone {
                if is_range_slice {
                    if node.left_type.is_ptr() {
                        g.write('*'.repeat(node.left_type.nr_muls()))
                    }
                    g.expr(node.left)
                } else {
                    g.gen_arg_from_type(left_type, node.left)
                }
            } else {
                if node.left_type.is_ptr() {
                    g.write('*'.repeat(node.left_type.nr_muls()))
                }
                g.expr(ast.Expr(node.left))
            }
            if node.kind == .repeat {
                g.write(', ')
                g.expr(node.args[0].expr)
            }
            if array_depth >= 0 {
                g.write(', ${array_depth}')
            }
            g.write(')')
        }
        else {
            return false
        }
    }

    return true
}

fn (mut g Gen) gen_fixed_array_method_call(node ast.CallExpr, left_type ast.Type) bool {
    match node.kind {
        .filter {
            g.gen_array_filter(node)
        }
        .index {
            g.gen_array_index(node, false)
        }
        .last_index {
            g.gen_array_index(node, true)
        }
        .contains {
            g.gen_array_contains(left_type, node.left, node.args[0].typ, node.args[0].expr)
        }
        .any {
            g.gen_array_any(node)
        }
        .count {
            g.gen_array_count(node)
        }
        .all {
            g.gen_array_all(node)
        }
        .map {
            g.gen_array_map(node)
        }
        .sort {
            g.gen_array_sort(node)
        }
        .sorted {
            g.gen_array_sorted(node)
        }
        .sort_with_compare {
            if !g.gen_array_sort_with_compare(node) {
                return false
            }
        }
        .sorted_with_compare {
            if !g.gen_array_sorted_with_compare(node) {
                return false
            }
        }
        .reverse {
            g.gen_fixed_array_reverse(node)
        }
        .reverse_in_place {
            g.gen_fixed_array_reverse_in_place(node)
        }
        else {
            return false
        }
    }

    return true
}

fn (mut g Gen) gen_to_str_method_call(node ast.CallExpr, unwrapped_rec_type ast.Type) bool {
    left_node := node.left
    mut rec_type := g.unwrap_generic(g.type_resolver.get_type_or_default(left_node,
        left_node.type()))
    if rec_type in [ast.void_type, ast.no_type] {
        rec_type = unwrapped_rec_type
    }
    if rec_type.has_flag(.shared_f) {
        rec_type = rec_type.clear_flag(.shared_f).set_nr_muls(0)
    }
    if left_node is ast.ComptimeSelector {
        if left_node.typ_key != '' {
            rec_type = g.type_resolver.get_ct_type_or_default(left_node.typ_key, rec_type)
            g.gen_expr_to_string(left_node, rec_type)
            return true
        }
    } else if left_node is ast.PostfixExpr {
        rec_type = g.type_resolver.get_type_or_default(left_node.expr, rec_type)
        if left_node.op == .question {
            rec_type = rec_type.clear_flag(.option)
        }
        g.gen_expr_to_string(left_node, rec_type)
        return true
    } else if left_node is ast.ComptimeCall {
        if left_node.kind == .method {
            sym := g.table.sym(g.unwrap_generic(left_node.left_type))
            if m := sym.find_method(g.comptime.comptime_for_method.name) {
                rec_type = m.return_type
                g.gen_expr_to_string(left_node, rec_type)
                return true
            }
        }
    } else if left_node is ast.Ident {
        if left_node.obj is ast.Var {
            if left_node.obj.ct_type_var != .no_comptime {
                rec_type = g.type_resolver.get_type(left_node)
                // In generic contexts, scope var types may be stale
                if g.cur_fn != unsafe { nil } && g.cur_concrete_types.len > 0
                    && left_node.obj.ct_type_var == .generic_param {
                    resolved := g.resolved_expr_type(left_node, rec_type)
                    if resolved != 0 {
                        rec_type = resolved
                    }
                }
                g.gen_expr_to_string(left_node, rec_type)
                return true
            } else if left_node.obj.smartcasts.len > 0 {
                rec_type = g.unwrap_generic(left_node.obj.smartcasts.last())
                cast_sym := g.table.sym(rec_type)
                if cast_sym.info is ast.Aggregate {
                    rec_type = cast_sym.info.types[g.aggregate_type_idx]
                }
                g.gen_expr_to_string(left_node, rec_type)
                return true
            } else if left_node.or_expr.kind == .propagate_option {
                g.gen_expr_to_string(left_node, g.unwrap_generic(node.left_type))
                return true
            }
        }
    } else if left_node is ast.None {
        g.gen_expr_to_string(left_node, ast.none_type)
        return true
    } else if node.left_type.has_flag(.option) {
        g.gen_expr_to_string(left_node, g.unwrap_generic(node.left_type))
        return true
    }
    if g.cur_fn != unsafe { nil } && g.cur_concrete_types.len > 0 {
        resolved_rec_type := g.resolved_expr_type(left_node, node.left_type)
        if resolved_rec_type != 0 && resolved_rec_type != ast.void_type {
            g.gen_expr_to_string(left_node,
                g.unwrap_generic(g.recheck_concrete_type(resolved_rec_type)))
            return true
        }
    }
    rec_sym := g.table.sym(rec_type)
    if g.alias_uses_parent_str(rec_sym) {
        rec_type = (rec_sym.info as ast.Alias).parent_type
    }
    g.get_str_fn(rec_type)
    return false
}

fn (g &Gen) alias_uses_parent_str(sym ast.TypeSymbol) bool {
    if sym.info !is ast.Alias || sym.has_method('str') {
        return false
    }
    alias_info := sym.info as ast.Alias
    parent_sym := g.table.sym(alias_info.parent_type)
    return parent_sym.is_string() || parent_sym.is_number()
        || parent_sym.kind in [.bool, .char, .byteptr, .charptr, .voidptr, .map]
}

fn (g &Gen) alias_keeps_parent_method_dispatch(sym ast.TypeSymbol, method_name string, kind ast.CallKind) bool {
    if sym.info !is ast.Alias || sym.has_method(method_name) {
        return false
    }
    return kind != .str || g.alias_uses_parent_str(sym)
}

// resolve_return_type resolves the generic return type of CallExpr
fn (mut g Gen) resolve_return_type(node ast.CallExpr) ast.Type {
    if node.is_method {
        if node.kind == .map && node.return_type != 0 && !node.return_type.has_flag(.generic)
            && !g.type_has_unresolved_generic_parts(node.return_type)
            && !(g.cur_fn != unsafe { nil } && g.cur_concrete_types.len > 0) {
            return if node.or_block.kind == .absent {
                g.unwrap_generic(g.recheck_concrete_type(node.return_type))
            } else {
                g.unwrap_generic(g.recheck_concrete_type(node.return_type)).clear_option_and_result()
            }
        }
        mut left_type := g.resolved_expr_type(node.left, node.left_type)
        if left_type == 0 || left_type == ast.void_type {
            left_type = node.left_type
        }
        left_type = g.recheck_concrete_type(left_type)
        if left_type == 0 || left_type == ast.void_type {
            return ast.void_type
        }
        left_sym := g.table.sym(left_type)
        final_left_sym := g.table.final_sym(g.unwrap_generic(left_type))
        if final_left_sym.kind == .map && node.kind in [.keys, .values] {
            map_info := final_left_sym.info as ast.Map
            return_type := if node.kind == .keys {
                ast.idx_to_type(g.table.find_or_register_array(map_info.key_type))
            } else {
                ast.idx_to_type(g.table.find_or_register_array(map_info.value_type))
            }
            return if node.or_block.kind == .absent {
                return_type
            } else {
                return_type.clear_option_and_result()
            }
        }
        if final_left_sym.kind == .map && node.name in ['clone', 'move'] {
            return g.unwrap_generic(left_type)
        }
        if final_left_sym.kind in [.array, .array_fixed] && !(left_sym.has_method(node.name)
            || left_sym.has_method_with_generic_parent(node.name)) && (node.name == 'get'
            || node.kind in [.first, .last, .pop_left, .pop, .map, .filter, .reverse, .clone, .clone_to_depth, .repeat, .trim, .slice, .sorted, .sorted_with_compare]) {
            return_type := g.resolved_array_builtin_method_return_type(node, left_type,
                node.return_type)
            return if node.or_block.kind == .absent {
                return_type
            } else {
                return_type.clear_option_and_result()
            }
        }
        if node.is_field {
            selector := ast.SelectorExpr{
                expr:       node.left
                expr_type:  left_type
                field_name: node.name
            }
            fn_typ := g.resolved_selector_field_type(selector, left_type)
            if fn_typ != 0 {
                fn_sym := g.table.final_sym(fn_typ.clear_option_and_result())
                if fn_sym.info is ast.FnType {
                    return_type :=
                        g.unwrap_generic(g.recheck_concrete_type(fn_sym.info.func.return_type))
                    if return_type != 0 {
                        return if node.or_block.kind == .absent {
                            return_type
                        } else {
                            return_type.clear_option_and_result()
                        }
                    }
                }
            }
        }
        func := left_sym.find_method_with_generic_parent(node.name) or {
            g.table.find_method(left_sym, node.name) or { return ast.void_type }
        }
        if func.return_type != 0 && !func.return_type.has_flag(.generic)
            && !g.type_has_unresolved_generic_parts(func.return_type) {
            return if node.or_block.kind == .absent {
                func.return_type
            } else {
                func.return_type.clear_option_and_result()
            }
        }
        receiver_concrete_types, parent_method := g.receiver_generic_call_context(left_type,
            node.name)
        if func.generic_names.len > 0 {
            mut concrete_types := if node.concrete_types.len == func.generic_names.len
                && node.concrete_types.all(it != 0 && !it.has_flag(.generic)
                && !g.type_has_unresolved_generic_parts(it)) {
                node.concrete_types.map(g.unwrap_generic(it))
            } else if node.raw_concrete_types.len > 0 {
                node.raw_concrete_types.map(g.unwrap_generic(it))
            } else {
                node.concrete_types.map(g.unwrap_generic(it))
            }
            if concrete_types.len == 0 && receiver_concrete_types.len > 0 {
                concrete_types = receiver_concrete_types.clone()
            } else if receiver_concrete_types.len > 0 && concrete_types.len < func.generic_names.len
                && receiver_concrete_types.len + concrete_types.len == func.generic_names.len {
                method_concrete_types := concrete_types.clone()
                concrete_types = receiver_concrete_types.clone()
                concrete_types << method_concrete_types
            }
            if receiver_concrete_types.len > 0 {
                for i, receiver_ct in receiver_concrete_types {
                    if i < concrete_types.len {
                        concrete_types[i] = receiver_ct
                    }
                }
            }
            mut rec_len := 0
            if left_type.has_flag(.generic) {
                rec_sym := g.table.final_sym(g.unwrap_generic(left_type))
                match rec_sym.info {
                    ast.Struct, ast.Interface, ast.SumType {
                        rec_len += rec_sym.info.generic_types.len
                    }
                    else {}
                }
            }
            if g.cur_fn != unsafe { nil } && g.cur_concrete_types.len > 0 {
                offset := if func.is_method { 1 } else { 0 }
                receiver_param_type := if func.params.len > 0 {
                    func.params[0].typ
                } else {
                    ast.no_type
                }
                mut generic_arg_idx := 0
                for i, arg in node.args {
                    param := if func.is_variadic && i >= func.params.len - (offset + 1) {
                        func.params.last()
                    } else {
                        func.params[offset + i]
                    }
                    if !param.typ.has_flag(.generic) || param.typ == receiver_param_type {
                        continue
                    }
                    slot := rec_len + generic_arg_idx
                    generic_arg_idx++
                    // Only override if the current concrete type is still unresolved.
                    // The checker already resolves concrete types correctly (e.g. T=int for []T with []int arg),
                    // so we should not overwrite already-resolved values with the full argument type
                    // (which would turn T=int into T=[]int, causing []T to resolve to [][]int).
                    if slot < concrete_types.len {
                        current_type := concrete_types[slot]
                        if current_type != 0 && current_type != ast.void_type
                            && !current_type.has_flag(.generic)
                            && !g.type_has_unresolved_generic_parts(current_type) {
                            // When the arg is a generic_param variable, the checker's concrete type
                            // may be stale (from a different instantiation). Re-resolve from
                            // g.cur_concrete_types and override if different.
                            if arg.expr is ast.Ident && arg.expr.obj is ast.Var
                                && (arg.expr.obj as ast.Var).ct_type_var == .generic_param && g.table.sym(param.typ).name in func.generic_names {
                                mut resolved :=
                                    g.resolve_current_fn_generic_param_type(arg.expr.name)
                                if (arg.is_mut || (arg.expr.obj as ast.Var).is_mut)
                                    && resolved.is_ptr() {
                                    resolved = resolved.deref()
                                }
                                if resolved != 0 && resolved != ast.void_type
                                    && resolved != current_type {
                                    concrete_types[slot] = resolved
                                }
                            }
                            continue
                        }
                    }
                    mut resolved_arg_type := ast.void_type
                    if arg.expr is ast.Ident && arg.expr.obj is ast.Var
                        && (arg.expr.obj as ast.Var).ct_type_var == .generic_param {
                        resolved_arg_type = g.resolve_current_fn_generic_param_type(arg.expr.name)
                        if (arg.is_mut || (arg.expr.obj as ast.Var).is_mut)
                            && resolved_arg_type.is_ptr() {
                            resolved_arg_type = resolved_arg_type.deref()
                        }
                    }
                    if resolved_arg_type == ast.void_type {
                        resolved_arg_type = g.resolved_generic_call_arg_type(arg)
                    }
                    if arg.expr.is_auto_deref_var() && resolved_arg_type.is_ptr()
                        && !param.typ.is_ptr() {
                        resolved_arg_type = resolved_arg_type.deref()
                    }
                    if resolved_arg_type.clear_option_and_result() == ast.none_type {
                        continue
                    }
                    if resolved_arg_type != 0 && resolved_arg_type != ast.void_type
                        && !resolved_arg_type.has_flag(.generic)
                        && !g.type_has_unresolved_generic_parts(resolved_arg_type)
                        && slot < concrete_types.len {
                        g.infer_generic_call_concrete_types_from_types(func.generic_names, mut
                            concrete_types, arg, param.typ, resolved_arg_type)
                    }
                }
            }

            mut call_ := unsafe { node }
            comptime_args := g.type_resolver.resolve_args(g.cur_fn, func, mut call_, concrete_types)
            if concrete_types.len > 0 {
                for k, v in comptime_args {
                    slot := rec_len + k
                    if slot < concrete_types.len {
                        current_type := concrete_types[slot]
                        if current_type == ast.void_type || current_type.has_flag(.generic)
                            || g.type_has_unresolved_generic_parts(current_type) {
                            concrete_types[slot] = g.unwrap_generic(v)
                        }
                    }
                }
            }
            // Prefer the resolved method declaration over the cached call metadata here.
            // Generic rechecks can leave `node.return_type_generic` stale even when the
            // method's concrete type arguments have since been corrected.
            mut return_type_candidates := []ast.Type{}
            if func.return_type != 0 {
                return_type_candidates << func.return_type
            }
            if node.return_type_generic != ast.void_type && node.return_type_generic != 0
                && node.return_type_generic !in return_type_candidates {
                return_type_candidates << node.return_type_generic
            }
            if parent_method.params.len > 0 && parent_method.return_type != 0
                && parent_method.return_type !in return_type_candidates {
                return_type_candidates << parent_method.return_type
            }
            for return_type_generic in return_type_candidates {
                if gen_type := g.table.convert_generic_type(return_type_generic,
                    func.generic_names, concrete_types)
                {
                    if !gen_type.has_flag(.generic) {
                        return if node.or_block.kind == .absent {
                            gen_type
                        } else {
                            gen_type.clear_option_and_result()
                        }
                    }
                }
            }
        }
        if parent_method.params.len > 0 && receiver_concrete_types.len > 0 {
            parent_return_type_generic := if node.return_type_generic != ast.void_type
                && node.return_type_generic != 0 {
                node.return_type_generic
            } else {
                parent_method.return_type
            }
            receiver_generic_names := g.table.generic_type_names(parent_method.params[0].typ)
            if receiver_generic_names.len == receiver_concrete_types.len {
                if gen_type := g.table.convert_generic_type(parent_return_type_generic,
                    receiver_generic_names, receiver_concrete_types)
                {
                    if !gen_type.has_flag(.generic) {
                        return if node.or_block.kind == .absent {
                            gen_type
                        } else {
                            gen_type.clear_option_and_result()
                        }
                    }
                }
            }
        }
    } else if node.is_static_method {
        // For static method calls like T.from(s) or T.parse(mut p) in generic contexts,
        // node.return_type may be stale from a previous checker instantiation.
        // Resolve from left_type which retains the .generic flag.
        if node.left_type.has_flag(.generic) && g.cur_fn != unsafe { nil }
            && g.cur_concrete_types.len > 0 {
            resolved_left := g.unwrap_generic(g.recheck_concrete_type(node.left_type))
            if resolved_left != ast.void_type && resolved_left != 0 {
                mut ret := resolved_left
                if node.return_type.has_flag(.result) {
                    ret = ret.set_flag(.result)
                } else if node.return_type.has_flag(.option) {
                    ret = ret.set_flag(.option)
                }
                return if node.or_block.kind == .absent {
                    ret
                } else {
                    ret.clear_option_and_result()
                }
            }
        }
        ret_type := g.unwrap_generic(g.recheck_concrete_type(node.return_type))
        return if node.or_block.kind == .absent {
            ret_type
        } else {
            ret_type.clear_option_and_result()
        }
    } else {
        mut fn_var_type := ast.void_type
        lookup_name := if node.left is ast.Ident { node.left.name } else { node.name }
        resolved_current_type := g.resolve_current_fn_generic_param_type(lookup_name)
        if resolved_current_type != 0
            && g.table.final_sym(g.unwrap_generic(resolved_current_type)).kind == .function {
            fn_var_type = g.unwrap_generic(g.recheck_concrete_type(resolved_current_type))
        } else if node.is_fn_var {
            fn_var_type = g.unwrap_generic(g.recheck_concrete_type(node.fn_var_type))
        }
        if fn_var_type == 0 {
            if obj := node.scope.find_var(lookup_name) {
                if g.table.final_sym(g.unwrap_generic(obj.typ)).kind == .function {
                    fn_var_type = g.unwrap_generic(g.recheck_concrete_type(obj.typ))
                }
            }
        }
        if fn_var_type != 0 {
            fn_sym := g.table.final_sym(fn_var_type)
            if fn_sym.info is ast.FnType {
                return_type :=
                    g.unwrap_generic(g.recheck_concrete_type(fn_sym.info.func.return_type))
                if return_type != 0 {
                    return if node.or_block.kind == .absent {
                        return_type
                    } else {
                        return_type.clear_option_and_result()
                    }
                }
            }
        }
        if func := g.table.find_fn(node.name) {
            if func.generic_names.len > 0 {
                mut concrete_types := g.generic_fn_call_concrete_types(func, node)
                mut call_ := unsafe { node }
                comptime_args := g.type_resolver.resolve_args(g.cur_fn, func, mut call_,
                    concrete_types)
                if concrete_types.len > 0 {
                    for k, v in comptime_args {
                        if k < concrete_types.len {
                            current_type := concrete_types[k]
                            if current_type == ast.void_type || current_type.has_flag(.generic)
                                || g.type_has_unresolved_generic_parts(current_type) {
                                concrete_types[k] = g.unwrap_generic(v)
                            }
                        }
                    }
                }
                return_type_generic := if node.return_type_generic != ast.void_type {
                    node.return_type_generic
                } else {
                    func.return_type
                }
                if gen_type := g.table.convert_generic_type(return_type_generic,
                    func.generic_names, concrete_types)
                {
                    if !gen_type.has_flag(.generic) {
                        return if node.or_block.kind == .absent {
                            gen_type
                        } else {
                            gen_type.clear_option_and_result()
                        }
                    }
                }
            }
        }
    }
    return ast.void_type
}

fn (mut g Gen) resolved_array_builtin_method_return_type(node ast.CallExpr, left_type ast.Type, fallback ast.Type) ast.Type {
    mut return_type := g.unwrap_generic(g.recheck_concrete_type(fallback))
    resolved_left_type := g.recheck_concrete_type(g.resolved_expr_type(node.left, left_type))
    if resolved_left_type == 0 {
        return return_type
    }
    resolved_left_sym := g.table.final_sym(g.unwrap_generic(resolved_left_type))
    if resolved_left_sym.kind !in [.array, .array_fixed] {
        return return_type
    }
    if node.name == 'get' {
        elem_type := if resolved_left_sym.info is ast.Array {
            resolved_left_sym.info.elem_type
        } else if resolved_left_sym.info is ast.ArrayFixed {
            resolved_left_sym.info.elem_type
        } else {
            return return_type
        }
        if elem_type == 0 {
            return return_type
        }
        return g.unwrap_generic(g.recheck_concrete_type(elem_type.set_flag(.option)))
    }
    match node.kind {
        .map {
            if node.args.len == 0 {
                return return_type
            }
            arg := node.args[0]
            arg_type := g.unwrap_generic(g.recheck_concrete_type(g.resolved_expr_type(arg.expr,
                arg.typ)))
            if arg_type == 0 {
                return return_type
            }
            arg_sym := g.table.final_sym(g.unwrap_generic(arg_type))
            mapped_type := match arg_sym.info {
                ast.FnType {
                    if arg.expr is ast.SelectorExpr {
                        arg_type
                    } else {
                        arg_sym.info.func.return_type
                    }
                }
                else {
                    arg_type
                }
            }

            resolved_mapped_type := g.unwrap_generic(g.recheck_concrete_type(mapped_type))
            if resolved_mapped_type == 0 {
                return return_type
            }
            return g.table.find_or_register_array(resolved_mapped_type)
        }
        .filter, .reverse, .clone, .clone_to_depth, .repeat, .trim, .slice, .sorted,
        .sorted_with_compare {
            // These methods return a new array by value, never a pointer.
            // Strip pointer flags from mut receivers.
            mut ret := g.unwrap_generic(resolved_left_type).set_nr_muls(0)
            // .filter on a fixed array returns a dynamic array since the
            // result size is determined at runtime.
            if node.kind == .filter && resolved_left_sym.kind == .array_fixed {
                info := resolved_left_sym.info as ast.ArrayFixed
                ret = ast.new_type(g.table.find_or_register_array(info.elem_type))
            }
            return ret
        }
        .first, .last, .pop_left, .pop {
            elem_type := if resolved_left_sym.info is ast.Array {
                resolved_left_sym.info.elem_type
            } else if resolved_left_sym.info is ast.ArrayFixed {
                resolved_left_sym.info.elem_type
            } else {
                return return_type
            }
            if elem_type == 0 {
                return return_type
            }
            return g.unwrap_generic(g.recheck_concrete_type(elem_type))
        }
        else {}
    }

    return return_type
}

fn (mut g Gen) resolve_receiver_name(node ast.CallExpr, unwrapped_rec_type ast.Type, final_left_sym ast.TypeSymbol,
    left_sym ast.TypeSymbol, typ_sym ast.TypeSymbol) string {
    mut receiver_type_name := util.no_dots(g.cc_type(unwrapped_rec_type, false))
    if final_left_sym.kind == .map && node.kind in [.clone, .move] {
        receiver_type_name = 'map'
    }
    if final_left_sym.kind == .array && !(left_sym.kind == .alias && left_sym.has_method(node.name))
        && node.kind in [.clear, .repeat, .sort_with_compare, .sorted_with_compare, .push_many, .trim, .first, .last, .pop_left, .pop, .clone, .clone_to_depth, .reverse, .slice, .pointers] {
        if !(left_sym.info is ast.Alias && typ_sym.has_method(node.name)) {
            // `array_Xyz_clone` => `builtin__array_clone`
            receiver_type_name = 'array'
        }
    }
    return receiver_type_name
}

fn (mut g Gen) receiver_generic_call_context(left_type ast.Type, method_name string) ([]ast.Type, ast.Fn) {
    mut exact_method := ast.Fn{}
    mut exact_method_exists := false
    if left_type != 0 {
        if method := g.receiver_exact_method_for_type(left_type, method_name) {
            exact_method = method
            exact_method_exists = true
        }
    }
    mut has_structured_method_for_exact := false
    if structured_method := g.table.find_structured_receiver_method_with_types(left_type,
        method_name)
    {
        if exact_method_exists {
            has_structured_method_for_exact = true